1. Epic GamesDeveloper
  3. 2. Cómo encontrar jugadores en tiempo de ejecución

2. Cómo encontrar jugadores en tiempo de ejecución

Utiliza Verse para encontrar jugadores y equipos en tiempo de ejecución.

2. Cómo encontrar jugadores en tiempo de ejecución
Prerequisite topics

In order to understand and use the content on this page, make sure you are familiar with the following topics:

Esta sección muestra cómo encontrar en tiempo de ejecución los jugadores y equipos que configuraste anteriormente.

Cómo definir miembros de clases

  1. Abre el explorador de Verse y haz doble clic en triad_infiltration_game.verse para abrir la secuencia de comandos en Visual Studio Code.
  2. En la parte superior del archivo, añade using { /Verse.org/Random } para acceder a la función Shuffle(). Lo utilizarás para mezclar aleatoriamente equipos de jugadores antes de equilibrar. Añade también using { /Fortnite.com/FortPlayerUtilities } para acceder a la función Respawn() de los jugadores, que utilizarás más tarde para teletransportar a los jugadores a sus zonas de aparición al inicio de la partida. 
     using { /Fortnite.com/Devices }
 using { /Fortnite.com/FortPlayerUtilities }
 using { /Verse.org/Simulation }
 using { /Verse.org/Random }
 using { /UnrealEngine.com/Temporary/Diagnostics }
  3. En la definición de la clase triad_infiltration_game, añade los siguientes campos:
    1. Tres enteros editables denominados MaximumInfiltrators, MaximumAttackers y MaximumDefenders. Inicializa MaximumInfiltrators a 2 y MaximumAttackers y MaximumDefenders a 4. Estos registran el número máximo de jugadores de cada equipo; los utilizarás para equilibrar los equipos dinámicamente. Puedes cambiar estos números para hacer pruebas y crear variaciones interesantes en el juego. 
       triad_infiltration := class(creative_device):

     # Para evitar que los jugadores no puedan unirse a un equipo, debes establecer el número máximo
     # de jugadores en la configuración de la isla para la suma de todas las variables Maximum(Team).

     # Número máximo de jugadores en el equipo de infiltrados.
     @editable
     MaximumInfiltrators:int = 2

     # Número máximo de jugadores en el equipo de atacantes.
     @editable
     MaximumAttackers:int = 4

     # Número máximo de jugadores en el equipo de defensores.
     @editable
     MaximumDefenders:int = 4
    2. Un map de variables llamado TeamsAndTotals. Esto asignará equipos de jugadores al número máximo de jugadores de ese equipo. 
       # Número máximo de jugadores en el equipo de infiltrados.
 @editable
 MaximumInfiltrators:int = 2

 # Número máximo de jugadores en el equipo de atacantes.
 @editable
 MaximumAttackers:int = 4

 # Número máximo de jugadores en el equipo de defensores.
 @editable
 MaximumDefenders:int = 4

 # Mapa de equipos con su número máximo de jugadores.
 var TeamsAndTotals:[team]int = map{}
    3. Una matriz editable de teletransportadores llamada Teleporters. Contiene una referencia a los teletransportadores que utilizarás para teletransportar a los jugadores a sus lugares de aparición después de equilibrar el equipo. 
       # Mapa de equipos con su número máximo de jugadores.
 var TeamsAndTotals:[team]int = map{}

 # Matriz de teletransportadores que teletransportan a los jugadores al punto de aparición de su equipo cuando se inicia la partida. 
 @editable
 Teleporters:[]teleporter_device = array{}
    4. Una matriz item_granter_device editable llamada WeaponGranters. Almacena los repartidores de objetos necesarios para conceder a los jugadores un arma en función de su equipo cuando aparecen. 
       # Matriz de teletransportadores que teletransportan a los jugadores al punto de aparición de su equipo cuando se inicia la partida. 
 @editable
 Teleporters:[]teleporter_device = array{}

 # Matriz de repartidores de armas para cada equipo.
 @editable
 var WeaponGranters:[]item_granter_device = array{}
    5. Tres variables team opcionales denominadas MaybeInfiltrators, MaybeAttackers y MaybeDefenders. Almacenan una referencia a cada equipo para que puedas comprobar que los equipos están configurados correctamente. 
       # Matriz de repartidores de armas para cada equipo.
 @editable
 var WeaponGranters:[]item_granter_device = array{}

 # Referencia al equipo de infiltrados.
 var MaybeInfiltrators:?team = false

 # Referencia al equipo de atacantes.
 var MaybeAttackers:?team = false

 # Referencia al equipo de defensores.
 var MaybeDefenders:?team = false
    6. Una matriz variable de equipos llamada Teams. Contiene una referencia a todos los equipos del juego, y la utilizarás para establecer las variables opcionales de equipo anteriores, así como para encontrar equipos a los que asignar jugadores al equilibrar. 
       # Referencia al equipo de infiltrados.
 var MaybeInfiltrators:?team = false

 # Referencia al equipo de atacantes.
 var MaybeAttackers:?team = false

 # Referencia al equipo de defensores.
 var MaybeDefenders:?team = false

 # Matriz de todos los equipos en el juego.
 var Teams:[]team = array{}

Cómo encontrar jugadores y equipos en tiempo de ejecución

  1. En OnBegin(), actualiza la matriz Teams con cada equipo que hayas configurado antes en Configuración de la experiencia. Puedes utilizar la función GetTeams() de la API fort_team_collection para obtener una matriz de todos los equipos del espacio de juego. 
     OnBegin<override>()<suspends>:void =
     # Obtiene todos los equipos.
     set Teams = GetPlayspace().GetTeamCollection().GetTeams()
  2. Guarda una referencia a cada equipo al asignar MaybeInfiltrators, MaybeAttackers y MaybeDefenders a sus respectivos equipos en la matriz Teams. 
     # Guarda los equipos para hacer referencia a ellos más tarde.
 set MaybeInfiltrators = option{Teams[0]}
 set MaybeAttackers = option{Teams[1]}
 set MaybeDefenders = option{Teams[2]}
  3. Ahora comprueba si los tres equipos se han configurado correctamente. Como MaybeInfiltrators, MaybeAttackers y MaybeDefenders son cada una option, puedes hacer esto comprobando si contienen un valor real. Si es así, establece el valor de cada equipo en TeamsAndTotals en el número máximo de jugadores para ese equipo. 
     if:
     Infiltrators := MaybeInfiltrators?
     Attackers := MaybeAttackers?
     Defenders :=  MaybeDefenders?
     Logger.Print("Encontrados los tres equipos")
     set TeamsAndTotals[Infiltrators] = MaximumInfiltrators
     set TeamsAndTotals[Attackers] = MaximumAttackers
     set TeamsAndTotals[Defenders] = MaximumDefenders
     Logger.Print("Configura los tres equipos en TeamsAndTotals")
 else:
     Logger.Print("No se han encontrado todos los equipos, asegúrate de asignar los equipos correctos en la configuración de tu isla.")

  4. Tu código de triad_infiltration_game debería tener el siguiente aspecto:

     triad_infiltration_game := class(creative_device):

     Logger:log = log{Channel := triad_infiltration_log_channel}

     # Para evitar que los jugadores no puedan unirse a un equipo, debes establecer el número máximo
     # de jugadores en la configuración de la isla para la suma de todas las variables Maximum(Team).
    
     # Número máximo de jugadores en el equipo de infiltrados.
     @editable
     MaximumInfiltrators:int = 2
    
     # Número máximo de jugadores en el equipo de atacantes.
     @editable
     MaximumAttackers:int = 4
    
     # Número máximo de jugadores en el equipo de defensores.
     @editable
     MaximumDefenders:int = 4
    
     # Matriz de teletransportadores que teletransportan a los jugadores al punto de aparición de su equipo cuando se inicia la partida. 
     @editable
     Teleporters:[]teleporter_device = array{}
    
     # Matriz de repartidores de armas para cada equipo.
     @editable
     var WeaponGranters:[]item_granter_device = array{}
    
     # Matriz de generadores de jugadores para cada equipo.
     @editable
     PlayersSpawners:[]player_spawner_device = array{}
        
     # Referencia al equipo de infiltrados.
     var MaybeInfiltrators:?team = false
    
     # Referencia al equipo de atacantes.
     var MaybeAttackers:?team = false
    
     # Referencia al equipo de defensores.
     var MaybeDefenders:?team = false
    
     # Matriz de todos los equipos en el juego.
     var Teams:[]team = array{}
        
     # Mapa de equipos con su número máximo de jugadores.
     var TeamsAndTotals:[team]int = map{}
    
     OnBegin<override>()<suspends>:void =
         # Obtiene todos los equipos
         set Teams = GetPlayspace().GetTeamCollection().GetTeams()
         # Guarda los equipos para hacer referencia a ellos más tarde
         set MaybeInfiltrators = option{Teams[0]}
         set MaybeAttackers = option{Teams[1]}
         set MaybeDefenders = option{Teams[2]}

         if:
             Infiltrators := MaybeInfiltrators?
             Attackers := MaybeAttackers?
             Defenders :=  MaybeDefenders?
             Logger.Print("Encontrados los tres equipos")
             set TeamsAndTotals[Infiltrators] = MaximumInfiltrators
             set TeamsAndTotals[Attackers] = MaximumAttackers
             set TeamsAndTotals[Defenders] = MaximumDefenders
             Logger.Print("Configura los tres equipos en TeamsAndTotals")            
         else:
             Logger.Print("No se han encontrado todos los equipos, asegúrate de asignar los equipos correctos en la configuración de tu isla.")

  5. Guarda la secuencia de comandos en Visual Studio Code y, en el menú principal, debajo de Verse, haz clic en Compilar secuencias de comandos de Verse para actualizar tu dispositivo creado con Verse en el nivel.

  6. Haz clic en Abrir sesión en la barra de herramientas de UEFN para poner a prueba el nivel. Cuando pruebes tu nivel, los tres equipos deben estar configurados en TeamsAndTotals. Comprueba este comportamiento con el registro.

    Los tres equipos encontrados

Siguiente paso

En el siguiente paso de este tutorial, aprenderás a equilibrar equipos de jugadores de forma asimétrica al comienzo de una partida.

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page