1. Epic GamesDeveloper
  3. 3. Die Lichter zur Laufzeit mit Gameplay-Tags finden

3. Die Lichter zur Laufzeit mit Gameplay-Tags finden

Erstelle ein Rätsel, bei dem der Spieler mit einem in Verse erstellten Gerät die richtige Kombination aus ein- und ausgeschalteten Lichtern finden muss, um ein Item zu spawnen.

3. Die Lichter zur Laufzeit mit Gameplay-Tags finden
Prerequisite topics

In order to understand and use the content on this page, make sure you are familiar with the following topics:

Wenn du diesen Schritt im Tagged Lights Puzzle Tutorial abschließt, lernst du, wie du Gameplay-Tags verwenden kannst, um Actors zu finden, die mit einem bestimmten Tag markiert sind, während das Spiel läuft. Mit Gameplay-Tags kannst du mit mehreren Geräten arbeiten, ohne dass du ihre Referenzen im Editor einrichten musst. So können sich interessante Spielgelegenheiten ergeben, indem dein Code beispielsweise dynamisch ändert, welche Geräte aktiv sind, während der Spieler im Spiel voranschreitet.

Befolge diese Schritte, um ein neues Gameplay-Tag zu erstellen und es für das Rätsel allen Lichtern im Level zuzuweisen:

  1. Öffne den Verse-Explorer und klicke doppelt auf tagged_lights_puzzle.verse, um das Script in Visual Studio Code zu öffnen.
  2. Oben in der Codedatei:
    • Fügeusing { /Verse.org/Simulation/Tags } hinzu, um die Klasse tag zu referenzieren und die Funktion GetCreativeObjectsWithTags() zu verwenden.
    • Füge using { /Verse.org/Simulation } hinzu, um bearbeitbare Eigenschaften erstellen zu können.
     using { /Fortnite.com/Devices }
 using { /Verse.org/Native }
 using { /UnrealEngine.com/Temporary/Diagnostics }
 using { /Verse.org/Simulation/Tags }
 using { /Verse.org/Simulation }
    
 log_tagged_lights_puzzle := class(log_channel){}

  3. Füge über der Klasse log_tagged_lights_puzzle eine neue Subklasse mit dem Namen puzzle_light hinzu, die von der Klasse tag erbt. Der geerbte Klassenname wird zu einem benutzerdefinierten Gameplay-Tag, das du auf jedem Kreativgerät verwenden kannst.

     # Leite die `tag`-Klasse im Verse.org/Simulation/Tags-Modul ab, um ein neues Gameplay-Tag zu erstellen.
 puzzle_light := class(tag){}

 log_tagged_lights_puzzle := class(log_channel){}
  4. Klicke in der UEFN-Symbolleiste auf Build Verse Scripts, um deinen Code und dein neues puzzle_light Gameplay-Tag in dein Projekt zu kompilieren.
  5. Wähle im Outliner von UEFN ein Benutzerdefiniertes-Licht-Gerät aus, um sein Detail-Panel zu öffnen.
  6. Im Detail-Panel:
    1. Klicke auf Neue Komponente hinzufügen und wähle Verse Tag Markup.
    2. Wähle die Komponente VerseTagMarkup aus, um ihre Einstellungen im Tab „Details“ anzuzeigen.
    3. Bearbeite unter Gameplay Tags die Eigenschaft Tags und füge den Tag puzzle_light hinzu.
    Die Komponente VerseTagMarkup und den Tag puzzle_light hinzufügen

    Einem Gerät können mehrere Tags hinzugefügt werden, sodass jedes Gerät zu mehreren Gruppen zugleich gehören kann. Zum Beispiel wird ein Gerät mit tag1 und tag2 gefunden, wenn entweder GetCreativeObjectsWithTag(tag1{}) oder GetCreativeObjectsWithTag(tag2{}) aufgerufen wird.
  7. Füge in der Klassendefinition tagged_lights_puzzle zwei variable Matrix-Felder hinzu:
    • Eine bearbeitbare Logik-Variablen-Matrix mit dem Namen LightsState, um den aktuellen Zustand aller Lichter darzustellen (ob sie ein- oder ausgeschaltet sind). Es wird auch verwendet, um den Anfangszustand der Lichter festzulegen, daher sollte die Anzahl der Elemente mit der Anzahl der Lichter übereinstimmen, die mit dem Tag puzzle_light gekennzeichnet sind. In diesem Beispiel sind standardmäßig alle Lichter ausgeschaltet, sodass der Startwert für alle Lichter false ist. 
       @editable
 var LightsState : []logic = array{false, false, false, false}
    • Ein bearbeitbares customizable_light_device-Variablen-Array namens Lights, um alle Benutzerdefiniertes-Licht-Geräte zu speichern, die mit dem Gameplay-Tag puzzle_light gekennzeichnet sind. 
       @editable
 var Lights : []customizable_light_device = array{}
  8. Bei Spielbeginn sollte das Gerät die Lichter entsprechend der Anfangskonfiguration einrichten, die im LightsState-Array angegeben ist, und die Referenzen im Lights-Array speichern, damit sie aktualisiert werden können, wenn sich der Spielzustand ändert. Dies wird mit einer Methode namens SetupPuzzleLights() : void erreicht und in der Methode OnBegin() aufgerufen, sodass die Lichter bei Spielbeginn eingerichtet sind. 
     SetupPuzzleLights() : void =
     Logger.Print(“Setting up in-game lights”)
    
 OnBegin<override>()<suspends> : void =
     SetupPuzzleLights()
  9. Finde in SetupPuzzleLights() alle Geräte mit dem Tag puzzle_light, indem du GetCreativeObjectsWithTag(puzzle_light{}) aufrufst und speichere sie in einem Array namens TaggedActors. Da TaggedActors ein konstantes Array ist, das nur für die Methode SetupPuzzleLights() gilt, musst du nicht explizit einen Typ für das Array angeben, da er in diesem Kontext abgeleitet werden kann. 
     SetupPuzzleLights() : void =
     Logger.Print("In-game-Lichter werden eingerichtet")
     TaggedActors := GetCreativeObjectsWithTag(puzzle_light{})

    Verschiedene Aufrufe der Funktion GetCreativeObjectsWithTag() können die Geräte in unterschiedlicher Reihenfolge im Array-Ergebnis platzieren, da es beim Abrufen von Actors mit Gameplay-Tags keine garantierte Reihenfolge gibt.
  10. Nachdem du nun alle Geräte mit dem Tag puzzle_light gesammelt hast, stelle sicher, dass jedes Licht dem Anfangszustand entspricht, der durch die Matrix LightsState angegeben ist. Du kannst eine for-Schleife verwenden, um alle getaggten Geräte zu iterieren. 
     for:
     ActorIndex -> TaggedActor : TaggedActors
 do:
     TaggedActor
  11. Die Funktion GetCreativeObjectsWithTag() gibt ein Array vom Typ creative_object_interface zurück. In diesem Beispiel möchtest du mit jedem TaggedActor als customizable_light_device interagieren, damit du das Licht ein- oder ausschalten kannst.
    • Du kannst eine Klasse in eine ihrer Subklassen konvertieren (das nennt man Typecasting), indem du die Syntax NewDeviceReference := device_type_to_cast_to[DeviceReference] verwendest, wobei device_type_to_cast_to der gewünschte Gerätetyp ist, der in diesem Beispiel customizable_light_device ist. Dies ist ein fehlbarer Ausdruck, da die Typ-Umwandlung fehlschlägt, wenn das Gerät nicht in diesen Typ umgewandelt werden kann (z. B. wenn es sich um einen anderen Gerätetyp handelt). 
       LightDevice := customizable_light_device[TaggedActor]

    Die Funktion GetCreativeObjectsWithTag() hat den Rückgabetyp []creative_object_interface, weil die Funktion verschiedene Typen von Actors zurückgeben kann. Ihr Rückgabetyp ist also das interface, das alle Actors implementieren müssen, um von GetCreativeObjectsWithTag() zurückgegeben zu werden. Siehe Gameplay-Tags, um mehr zu erfahren.
    • Mit for-Ausdrücken kannst du fehlbare Ausdrücke als Filter verwenden und neue Variable erstellen, die du dann im for-Codeblock verwenden kannst. Füge in diesem Fall die Typkonvertierung zu customizable_light_device aus dem vorherigen Schritt zum Iterationsausdruck hinzu. 
       for:
      ActorIndex -> TaggedActor : TaggedActors
      LightDevice := customizable_light_device[TaggedActor]
 do:
      LightDevice
    • Der letzte Ausdruck in einem Codeblock ist das Ergebnis des Codeblocks. Der for-Ausdruck gibt das Ergebnis des Codeblocks jeder Iteration in einer Matrix zurück, sodass das Ergebnis dieses for-Ausdrucks eine Matrix von customize_light_device-Verweisen ist, die mit puzzle_light getaggt wurden. Das bedeutet, dass du die Matrix Lights direkt mit dem Ergebnis des for-Ausdrucks aktualisieren kannst. 
       set Lights = for:
      ActorIndex -> TaggedActor : TaggedActors
      LightDevice := customizable_light_device[TaggedActor]
 do:
      LightDevice
    • Diese for-Schleife sollte für die Lichter auch TurnOn() bzw. TurnOff() aufrufen, damit sie mit ihrem LightsState-Anfangszustand im Editor übereinstimmen. Der Ausdruck for kann den Index zurückgeben, der verwendet wird, um das aktuelle getaggte Gerät zu erhalten (ActorIndex im Beispiel), das du verwenden kannst, um in das Array LightsState zu indizieren, um zu sehen, ob das Licht an oder aus sein soll. 
       set Lights = for:
      ActorIndex -> TaggedActor : TaggedActors
      LightDevice := customizable_light_device[TaggedActor]
      ShouldLightBeOn:= LightsState[ActorIndex]
 do:
      LightDevice
    • Rufe als nächstes TurnOn() / TurnOff() ab je nachdem, ob ShouldLightBeOn den Wert true oder false aufweist. Du kannst einen if-Ausdruck verwenden, um verschiedene Ausdrücke auf Basis einer Bedingung (spezifisch eines fehlbaren Ausdrucks) auszuführen. In diesem Fall kann der fehlbare Ausdruck den Abfrageoperator ? mit IsLightOn verwenden, was erfolgreich sein wird, wenn ShouldLightBeOn True ist (also rufe TurnOn() auf), und der fehlschlägt, wenn ShouldLightBeOn False ist (also rufe TurnOff() auf) 
       set Lights = for:
      ActorIndex -> TaggedActor : TaggedActors
      LightDevice := customizable_light_device[TaggedActor]
      ShouldLightBeOn := LightsState[ActorIndex]
 do:
      if (ShouldLightBeOn?) then LightDevice.TurnOn() else LightDevice.TurnOff()
      LightDevice
    • Es ist eine gute Idee, außerdem Index und Startwert des Lichts auszudrucken, damit du überprüfen kannst, ob dein Code wie erwartet funktioniert, und ihn mit der Situation im Level vergleichen kannst.
    • Wenn du {} in der Mitte eines Strings verwendest, wird der Ausdruck in {} zuerst ausgewertet, und sein Wert wird dem String hinzugefügt. Du kannst also einen if-Ausdruck in der Mitte eines Strings verwenden, um Werte bedingt hinzuzufügen. 
       set Lights = for:
      ActorIndex -> TaggedActor : TaggedActors
      LightDevice := customizable_light_device[ActorIndex]
      ShouldLightBeOn := LightsState[ActorIndex]
 do:
      Logger.Print("Adding Light at index {ActorIndex} with State:{if (ShouldLightBeOn?) then "On" else "Off"}")
      if (ShouldLightBeOn?) then LightDevice.TurnOn() else LightDevice.TurnOff()
      LightDevice
  12. Deine SetupPuzzleLights()-Methode sollte jetzt wie folgt aussehen: 
     SetupPuzzleLights() : void =
     TaggedActors := GetCreativeObjectsWithTag(puzzle_light{})
     <#
     Überprüfe bei jedem Gerät mit dem puzzle_light-Tag, ob es sich um ein customizable_light_device handelt, indem du versuchst, es auf diesen Typen anzuwenden.
     Ist dies der Fall, rufe seinen Anfangs-LightState ab, um TurnOn() oder TurnOff() auf das LightDevice anzuwenden.
     Speichere alle gekennzeichneten customizable_light_device im Lights-Array.
     #>
     set Lights = for:
             ActorIndex -> TaggedActor : TaggedActors
             LightDevice := customizable_light_device[TaggedActor]
             ShouldLightBeOn := LightsState[ActorIndex]
     do:
             Logger.Print("Adding Light at index {ActorIndex} with State:{if (ShouldLightBeOn?) then "On" else "Off"}")
             if (ShouldLightBeOn?) then LightDevice.TurnOn() else LightDevice.TurnOff()
             LightDevice
  13. Speichere das Script in Visual Studio Code.
  14. Klicke in der UEFN-Symbolleiste auf Build Verse Scripts (Verse-Scripte erstellen), um deinen Code zu kompilieren.
  15. Klicke in der UEFN-Symbolleiste auf Spielen, um das Level zu testen.

Wenn du dein Level testest, solltest du sehen, dass jedes Licht im Lights-Array mit seinem Anfangszustand im Output-Log gedruckt wird.

Nächster Schritt

Im nächsten Schritt dieses Tutorials erfährst du, wie du eine bestimmte Gruppe von Lichtern umschaltest, wenn der Spieler die Schaltflächen klickt.

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page