1. Epic GamesDeveloper
  3. 5. Nesneleri Ölçeklendirme

5. Nesneleri Ölçeklendirme

Verse ile obje ölçeklerini değiştirerek büyütüp küçültme işlemini öğren.

5. Nesneleri Ölçeklendirme

Bazen platform oyunlarında boyutları değişen engellerle karşılaşırsın. Bunlar, belirli bir eksen boyunca boyutları büyüyüp küçülen, uzayıp kısalan platformlar olabilir. Bir objenin boyutlarının bu şekilde değiştirilmesine ölçeğinin değiştirilmesi denir.

Bir objenin ölçeği, her boyutunun kendisine göre hangi değerle çarpılacağını gösterir. Normalde objelerin ölçeği {X := 1.0, Y := 1.0, Z := 1.0} şeklindedir. Bir obje ölçeğinin Z değerini iki katına çıkarırsan obje iki kat daha uzun olur. Uzunluğu yarıya düşürürsen yarısı kadar olur.

Ölçek, dönüşüm bulmacasının son kısmıdır. Bu bölümde farklı boyutlarda büyüyüp küçülen nesneler oluşturmak için ölçeği değiştirmeyi öğreneceksin.

Ölçeklenen Nesneler Yapma

Nesnelerinin ölçeklenmesini sağlayan kodu oluşturmak için şu adımları izle:

  1. Verse Gezgini ile movable_prop öğesinden devralınan scaling_prop adında yeni bir Verse sınıfı oluştur. Özelliklerini UEFN’de kullanıma açmak için bu sınıfa <concrete> ekle.

     # Belirli bir ölçeğe veya bir Kreatif nesnesi ölçeğine göre ölçeklenen bir nesne.
 scaling_prop<public> := class<concrete>(movable_prop):

  2. using { /Fortnite.com/Devices/CreativeAnimation } ve using { /UnrealEngine.com/Temporary/SpatialMath } ifadelerini dosyanın üst kısmına ekleyerek bu modülleri içe aktar. Nesnene animasyon uygulamak için bunlara ihtiyacın var. Ayrıca bu bölümde kullanılan araç ipuçlarına burada yer verilmiştir.

     using { /Fortnite.com/Devices }
 using { /Fortnite.com/Devices/CreativeAnimation }
 using { /Verse.org/Simulation }
 using { /UnrealEngine.com/Temporary/SpatialMath }

 MatchScaleTargetTip<localizes>:message = "Dünya alanına hareket etmek için isteğe bağlı konum. Bir MoveTarget ayarlamak istemezsen bunu kullan."

 # Belirli bir ölçeğe veya bir Kreatif nesnesi ölçeğine göre ölçeklenen bir nesne.
 scaling_prop<public> := class<concrete>(movable_prop):

  3. scaling_prop sınıf tanımının üst kısmına aşağıdaki alanları ekle.

    1. ScaleTargets için düzenlenebilir bir vector3 dizisi. Bunlar nesnenin büyüyüp küçüleceği ölçeklerdir. Move() tamamlandıktan sonra, nesne ölçeği bu değerle çarpılır.

       # RootProp’un ölçekleneceği vector3 hedefleri dizisi.
 @editable {ToolTip := MoveTargetsTip}
 var ScaleTargets:[]vector3= array{}

    2. MatchScaleTarget adlı bir düzenlenebilir isteğe bağlı creative_prop. Nesnenin başka bir nesne ölçeğiyle eşleşecek şekilde ölçeklenmesini istiyorsan ScaleTargets özelliğini kullanmak yerine bu değeri ayarlayabilirsin. Örneğin, sıfırlamadan önce tümü aynı boyuta ulaşan bir dizi platform oluşturmak istersen bu özelliği kullanabilirsin.

       # RootProp için ölçeğin eşleştirileceği isteğe bağlı Kreatif nesnesi.
 @editable {ToolTip := MatchScaleTargetTip}
 var MatchScaleTarget:?creative_prop = false

    3. TargetScale adında değişken bir rotation. Bu, nesnenin halihazırda ölçeklendiği ölçektir.

       # Nesnenin şu anda hedeflediği ölçektir.
 var TargetScale:vector3 = vector3{}

  4. Son sınıf tanımın şu şekilde görünmelidir:

     using { /Fortnite.com/Devices }
 using { /Fortnite.com/Devices/CreativeAnimation }
 using { /Verse.org/Simulation }
 using { /UnrealEngine.com/Temporary/SpatialMath }

 MatchScaleTargetTip<localizes>:message = "Dünya alanına hareket etmek için isteğe bağlı konum. Bir MoveTarget ayarlamak istemezsen bunu kullan."

 # Belirli bir ölçeğe veya bir kreatif nesnesi ölçeğine göre ölçeklenen bir nesne.
 scaling_prop<public> := class<concrete>(movable_prop):

     # RootProp’un ölçekleneceği vector3 hedefleri dizisi.
     @editable {ToolTip := MoveTargetsTip}
     var ScaleTargets:[]vector3= array{}

     # RootProp için ölçeğin eşleştirileceği isteğe bağlı kreatif nesnesi.
     @editable {ToolTip := MatchScaleTargetTip}
     var MatchScaleTarget:?creative_prop = false

     # Nesnenin şu anda hedeflediği ölçektir.
     var TargetScale:vector3 = vector3{}

  5. Nesneni movable_prop öğesinde hareket ettiren Move() fonksiyonunu zaten ayarladığın için bu sınıfta geçersiz kılabilirsin. scaling_prop sınıfında Move() fonksiyonunu geçersiz kıl. Move()dayken öncelikle MatchScaleTarget ayarının yapılıp yapılmadığını kontrol et ve bir ScaleToMatch değişkenine kaydet. Eğer öyleyse, TargetScale öğesini ScaleToMatch olarak ayarla ardından TargetScale, MoveDuration, MoveEaseType ve animation_mode.OneShot öğesini geçirerek MoveToEase() özelliğini çağır. Yalnızca ölçeği değiştiren ve daha önce aşırı yüklediğin MoveToEase() fonksiyonudur.

     # RootProp’u ScaleTarget veya ayarlanmışsa MatchScaleTarget öğesine doğru ölçeklendir.
 Move<override>()<suspends>:void=
     # Ayarlanmışsa, TargetScale öğesini MatchScaleTarget olarak ayarla.
     if:
         ScaleToMatch := MatchScaleTarget?.GetTransform().Scale
     then:
         set TargetScale = ScaleToMatch

         # Nesneyi ölçeklendirmeye başlamak için MoveToEase öğesini çağır. OneShot animasyon modu, animasyonu bir kez oynatır.
         RootProp.MoveToEase(MoveDuration, TargetScale, MoveEaseType, animation_mode.OneShot)

  6. MatchScaleTarget ayarlamadıysan, ScaleTargets dizini yinelemen gerekir. Bir for ifadesinde, ScaleTargets içindeki her bir ScaleTarget öğesini yinele ve TargetScale öğesini ScaleTarget olarak ayarla. Ardından daha önce olduğu gibi aynı değerleri geçirerek MoveToEase() öğesini çağır. Tamamlanmış Move() fonksiyonun şu şekilde görünmelidir:

     # RootProp’u ScaleTarget veya ayarlanmışsa MatchScaleTarget öğesine doğru ölçeklendir.
 Move<override>()<suspends>:void=

     # Ayarlanmışsa, TargetScale öğesini MatchScaleTarget olarak ayarla.
     if:
         ScaleToMatch := MatchScaleTarget?.GetTransform().Scale
     then:
         set TargetScale = ScaleToMatch

         # Nesneyi ölçeklendirmeye başlamak için MoveToEase öğesini çağır. OneShot animasyon modu, animasyonu bir kez oynatır.
         RootProp.MoveToEase(MoveDuration, TargetScale, MoveEaseType, animation_mode.OneShot)
     else:
         # Aksi halde ScaleTargets dizisindeki her bir hedefe ölçeklendir.
         for:
             ScaleTarget:ScaleTargets
         do:
             set TargetScale = ScaleTarget

             # Nesneyi ölçeklendirmeye başlamak için MoveToEase öğesini çağır. OneShot animasyon modu, animasyonu bir kez oynatır.
             RootProp.MoveToEase(MoveDuration, TargetScale, MoveEaseType, animation_mode.OneShot)

  7. prop_animator cihaz sınıfında, ScalingProps adında düzenlenebilir yeni bir scaling_prop dizisi ekle. Ölçeklenen tüm nesneler arasında dolaşan ve üzerine gelindiğinde Setup() özelliğini çağıran OnBegin() öğesine başka bir for ifadesi ekle. Güncellenen prop_animator sınıfın şu şekilde görünmelidir:

     using { /Fortnite.com/Devices }
 using { /Verse.org/Simulation }
 using { /UnrealEngine.com/Temporary/Diagnostics }

 TranslatingPropsTip<localizes>:message = "Animasyonu kullanarak yer değiştiren (hareket eden) nesneler."
 RotatingPropsTip<localizes>:message = "Animasyonu kullanarak dönen nesneler."
 ScalingPropsTip<localizes>:message = "Animasyonu kullanarak ölçeklenen nesneler."

 # Her bir nesnenin Setup() metodunu çağırarak, animasyonda hareket eden nesneleri koordine eder.
 prop_animator := class(creative_device):

     # Animasyon kullanılarak hareket ettirilen movable_props dizisi.
     @editable {ToolTip := TranslatingPropsTip}
     TranslatingProps:[]translating_prop = array{}

     # Animasyon kullanılarak döndürülen movable_props dizisi.
     @editable {ToolTip := RotatingPropsTip}
     RotatingProps:[]rotating_prop = array{}

     # Animasyon kullanılarak ölçeklendirilen movable_props dizisi.
     @editable {ToolTip := ScalingPropsTip}
     ScalingProps:[]scaling_prop = array{}

     # Cihaz, çalışmakta olan bir oyunda başlatıldığında çalışır
     OnBegin<override>()<suspends>:void=

         # Her bir nesne için Setup() özelliğini çağırarak animasyona başla.
         for:
             Prop:TranslatingProps
         do:
             Prop.Setup()
         for:
             Prop:RotatingProps
         do:
             Prop.Setup()
         for:
             Prop:ScalingProps
         do:
             Prop.Setup()

  8. Kodunu kaydet ve onu derle.

Nesneleri Cihazlara Bağlama

Editöre geri dönerek, başka bir boşluk oluşturmak için dönen nesneler bölümünden sonra ancak yükseltilmiş bloklardan önce var olan bazı nesneleri sil. Bölümüne bir FG01 Boks Eldiveni ekle. Eldiveni ScalingGlove olarak adlandır. Eldiveni boşluğun ortasına konumlandır ve yukarı bakacak şekilde döndür.

Boks eldiveni kurulumu. Eldiven, oyuncuları yükseltmek için asansör oluşturulacak şekilde ölçeklendirilir.

Anahat Düzenleyicisi içerisindeki nesne animatörünü seç ve eldivenin için ScalingProps öğesine bir dizi elementi ekle. Nesneye aşağıdaki değerleri ata:

Seçenek Değer Açıklama
ScaleTargets {1.0, 2.0, 1.0}, {1.0, 1.0, 1.0} Bu nesne, Y eksenindeki boyutlarının iki katına ölçeklenir ardından başlangıç boyutlarına geri ölçeklenir. Nesne döndürüldüğünden Y ekseninin artık nesneden yerel olarak “yukarıda” olduğunu unutma.
RootProp Animasyonunu yaptığın nesneye ata. Bu, animasyonunu yaptığın nesnedir.

Değişiklikleri uygula ardından nesnelerini kontrol et! Farklı boyutlar elde etmek için farklı ölçekler kullanmayı dene ayrıca farklı senaryolar oluşturmak için diğer nesneleri ölçeklendirmeyi dene!

Gelecek Ders

Sonraki bölümde, üçünü de yapabilen nesneler oluşturmak için hareketi, dönüşü ve ölçeklendirmeyi birleştireceksin!

%animating-prop-movement-6-combining-movement-rotation-and-scale-in-verse:topic%

Tam Kod

Bu bölümde oluşturulan kodun tamamı şöyledir:

scaling_prop.verse

using { /Fortnite.com/Devices }
using { /Fortnite.com/Devices/CreativeAnimation }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/SpatialMath }

MatchScaleTargetTip<localizes>:message = "Dünya alanına hareket etmek için isteğe bağlı konum. Bir MoveTarget ayarlamak istemezsen bunu kullan."

# Belirli bir ölçeğe veya bir kreatif nesnesi ölçeğine göre ölçeklenen bir nesne.
scaling_prop<public> := class<concrete>(movable_prop):

    # RootProp’un ölçekleneceği vector3 hedefleri dizisi.
    @editable {ToolTip := MoveTargetsTip}
    var ScaleTargets:[]vector3= array{}

    # RootProp için ölçeğin eşleştirileceği isteğe bağlı kreatif nesnesi.
    @editable {ToolTip := MatchScaleTargetTip}
    var MatchScaleTarget:?creative_prop = false

    # Nesnenin şu anda hedeflediği ölçektir.
    var TargetScale:vector3 = vector3{}
    
    # RootProp’u ScaleTarget veya ayarlanmışsa MatchScaleTarget öğesine doğru ölçeklendir.
    Move<override>()<suspends>:void=

        # Ayarlanmışsa, TargetScale öğesini MatchScaleTarget olarak ayarla. 
        if:
            ScaleToMatch := MatchScaleTarget?.GetTransform().Scale
        then:
            set TargetScale = ScaleToMatch
            
            # Nesneyi ölçeklendirmeye başlamak için MoveToEase öğesini çağır. OneShot animasyon modu, animasyonu bir kez oynatır. 
            RootProp.MoveToEase(MoveDuration, TargetScale, MoveEaseType, animation_mode.OneShot)
        else:
            # Aksi halde ScaleTargets dizisindeki her bir hedefe ölçeklendir.
            for:
                ScaleTarget:ScaleTargets
            do:
                set TargetScale = ScaleTarget

                # Nesneyi ölçeklendirmeye başlamak için MoveToEase öğesini çağır. OneShot animasyon modu, animasyonu bir kez oynatır. 
                RootProp.MoveToEase(MoveDuration, TargetScale, MoveEaseType, animation_mode.OneShot)

prop_animator.verse

using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/Diagnostics }

TranslatingPropsTip<localizes>:message = "Animasyonu kullanarak yer değiştiren (hareket eden) nesneler."
RotatingPropsTip<localizes>:message = "Animasyonu kullanarak dönen nesneler."
ScalingPropsTip<localizes>:message = "Animasyonu kullanarak ölçeklenen nesneler."

# Her bir nesnenin Setup() metodunu çağırarak, animasyonda hareket eden nesneleri koordine eder.
prop_animator := class(creative_device):

    # Animasyon kullanılarak hareket ettirilen movable_props dizisi.
    @editable {ToolTip := TranslatingPropsTip}
    TranslatingProps:[]translating_prop = array{}

    # Animasyon kullanılarak döndürülen movable_props dizisi.
    @editable {ToolTip := RotatingPropsTip}
    RotatingProps:[]rotating_prop = array{}

    # Animasyon kullanılarak ölçeklendirilen movable_props dizisi.
    @editable {ToolTip := ScalingPropsTip}
    ScalingProps:[]scaling_prop = array{}

    # Cihaz, çalışmakta olan bir oyunda başlatıldığında çalışır
    OnBegin<override>()<suspends>:void=

        # Her bir nesne için Setup() özelliğini çağırarak animasyona başla.
        for:
            Prop:TranslatingProps
        do:
            Prop.Setup()
        for:
            Prop:RotatingProps
        do:
            Prop.Setup()
        for:
            Prop:ScalingProps
        do:
            Prop.Setup()

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page