1. Epic GamesDeveloper
  3. 5. Como conceder armas na eliminação

5. Como conceder armas na eliminação

Use Verse para criar um modo de jogo competitivo multijogador que avança equipes por meio de uma série de armas.

5. Como conceder armas na eliminação
Prerequisite topics

In order to understand and use the content on this page, make sure you are familiar with the following topics:

Agora que você configurou seus mapas, o próximo passo é distribuir armas quando um jogador marcar uma eliminação.

Quando um jogador marca uma eliminação, você deve aplicar estas duas regras:

  1. Se o jogador não estiver no nível de arma mais alto em sua equipe, ou todos os jogadores estiverem no mesmo nível de arma, promova-o para o próximo nível de arma.

  2. Caso contrário, se houver um jogador em sua equipe com um nível de arma inferior, promova esse jogador.

Isso garantirá que os jogadores avancem pelas armas como uma equipe, e nenhum jogador estará mais de uma arma à frente ou atrás de qualquer um de seus companheiros de equipe.

Para fazer isso, você precisará saber quando um jogador marca uma eliminação e então comparar seu nível de arma com todos os outros jogadores de sua equipe e promover esse jogador com base nas duas regras acima.

Siga estas etapas para distribuir armas aos jogadores quando eles marcarem uma eliminação.

  1. Adicione um novo método GiveNextWeapon à classe team_elimination_game. Esse método concede a um jogador uma arma sempre que ele ou alguém de sua equipe marcar uma eliminação com base nas duas regras acima.

    ~~~(verse) GiveNextWeapon(EliminatingPlayer : agent) : void = Print("Encontrando um jogador para promover") ~~~

  2. Atualize OnPlayerEliminated para rastrear qual jogador marcou uma eliminação. Como OnPlayerEliminated aceita um elimination_result, você obtém referência a um personagem eliminado e um personagem eliminador. Como os jogadores podem ser eliminados por vários meios (como danos de queda, sentinelas, danos autoinfligidos, etc.), você precisa deduzir se EliminatingCharacter é um FortCharacter real (ou seja, um jogador real).

    • Obtenha uma referência a Result.EliminatingCharacter e salve-a em uma variável de opção local Eliminator. Verifique se Eliminator é um FortCharacter válido e, se for, salve o agente para esse caractere em outra variável EliminatorAgent. Por último, passe EliminatorAgent para GiveNextWeapon

      ~~~(verse) OnPlayerEliminated(Result : elimination_result) : void = Print("Um jogador foi eliminado!") Eliminator := Result.EliminatingCharacter if (FortCharacter := Eliminator?, EliminatorAgent := FortCharacter.GetAgent[]): GiveNextWeapon(EliminatorAgent) ~~~

  3. GiveNextWeapon precisa rastrear várias variáveis para distribuir ao jogador correto uma nova arma. Adicione as seguintes declarações a GiveNextWeapon.

    • Uma variável int WeaponTier. Isso rastreia o nível de arma do jogador para distribuir uma arma.

    • Uma variável agent opcional chamada MaybePlayerToGrant, que é o jogador a quem distribuir uma arma. Por padrão, este é o jogador passado para GiveNextWeapon.

    • Uma variável team opcional chamada MaybePlayerTeam, que é a equipe do jogador ao qual distribuir uma arma. Por padrão, essa é a equipe do jogador passada para GiveNextWeapon.

      ~~~(verse) GiveNextWeapon(EliminatingPlayer : agent) : void = Print("Encontrando um jogador para promover") var WeaponTier : int = 0 var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # O jogador ao qual conceder uma arma var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # A equipe da qual este jogador faz parte ~~~

  4. Extraia o valor de MaybePlayerTeam em uma variável local PlayerTeam e defina WeaponTier como o valor da pontuação do jogador em TeamMap.

    ~~~(verse) var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # A equipe da qual este jogador faz parte if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]): ~~~

  5. Itere através de cada jogador da equipe e compare seu nível de arma. Se você encontrar um jogador em um nível inferior, defina MaybePlayerToGrant para esse jogador e WeaponTier para sua pontuação. Observe que, como TeamMap é um mapa, você pode extrair a chave (jogador) e o valor (nível da arma) como variáveis locais usando a sintaxe Teammate -> TeammateTier.

    ~~~(verse) if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]): for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier): Print("Encontrado um colega de equipe com um nível inferior no nível {TeammateTier}") if(set WeaponTier = TeamMap[PlayerTeam][Teammate]): set MaybePlayerToGrant = option{Teammate} ~~~

  6. Depois de encontrar o jogador no nível de arma mais baixo (ou empatado no nível mais baixo), aumente em um o WeaponTier, em seguida defina a categoria da arma em TeamMap para WeaponTier.

    ~~~(verse) if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]): for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier): Print("Encontrado um colega de equipe com um nível inferior no nível {TeammateTier}") if(set WeaponTier = TeamMap[PlayerTeam][Teammate]): set MaybePlayerToGrant = option{Teammate}

    set WeaponTier = WeaponTier + 1 if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier): Print("A eliminação do nível de jogador agora é {WeaponTier}") ~~~

  7. Este é um bom lugar para verificar se um jogador ganhou o jogo, porque incrementar seu nível de arma pode empurrá-lo para além do número de eliminações necessárias para terminar o jogo.

    • Crie um novo método EndGame na classe team_elimination_game. Este método ativa o EndGameDevice no jogador especificado quando ele atinge o nível de arma final. O método concluído deve ter esta aparência:
     EndGame(InPlayer : agent) : void =
     Print("Jogador alcançou o Nível de Arma final, ativando EndGameDevice")
     EndGameDevice.Activate(InPlayer)

    • De volta a GiveNextWeapon, após incrementar o nível da arma do jogador, confira if WeaponTier >= EliminationsToEndGame. Em caso afirmativo, chame EndGame passando o jogador.

      ~~~(verse) if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier): Print("A eliminação do nível de jogador agora é {WeaponTier}")

    if(WeaponTier >= EliminationsToEndGame): EndGame(EliminatingPlayer) ~~~

  8. Caso contrário, chame GrantWeapon em GrantedPlayer.

    ~~~(verse) if(WeaponTier >= EliminationsToEndGame): EndGame(EliminatingPlayer)

    GrantWeapon(MaybePlayerToGrant, WeaponTier) ~~~

  9. O método GiveNextWeapon concluído deve se parecer com o seguinte código.

     GiveNextWeapon(EliminatingPlayer : agent) : void =
     Print("Encontrando um jogador para promover")
     var WeaponTier : int = 0
     var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # O jogador ao qual conceder uma arma
     var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # A equipe da qual este jogador faz parte
     if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
         for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
             Print("Encontrado um colega de equipe com um nível inferior no nível {TeammateTier}")
             if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
                 set MaybePlayerToGrant = option{Teammate}

     set WeaponTier = WeaponTier + 1
     if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
         Print("A eliminação do nível de jogador agora é {WeaponTier}")

     if(WeaponTier >= EliminationsToEndGame):
         EndGame(EliminatingPlayer)

     GrantWeapon(MaybePlayerToGrant, WeaponTier)

Salve o script no Visual Studio Code, compile-o e clique em Iniciar sessão na barra de ferramentas do UEFN para reproduzir o teste do nível. Ao testar seu nível, você deve surgir novamente com a primeira arma na matriz WeaponGranters. Verifique esse comportamento com o log. Marcar uma eliminação em um jogador inimigo deve promovê-lo para a próxima arma. As promoções devem seguir as duas regras descritas acima. Promover a arma final na sequência deve terminar o jogo com o jogador eliminador como vencedor.

Granting Weapons on Elimination

Próxima etapa

Na próxima etapa deste tutorial, você aprenderá a adicionar jogadores ao seu mapa e atribuir a eles uma arma quando eles entrarem em um jogo em andamento.

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page