3. ランタイム時にゲームプレイ タグでライトを見つける

「タグ付きライト パズル」チュートリアルのこのステップを完了すると、ゲーム実行中に特定のタグでマークされたアクタを見つけるために ゲームプレイ タグ を使用する方法を習得できます。 ゲームプレイ タグにより、複数の仕掛けを、エディタでそれらの参照をセットアップすることなく操作することができます。 これを利用して、ゲームプレイをさらに面白く発展させることができます。たとえば、プレイヤーがゲームを進めていくにつれてどの仕掛けをアクティブにするかを、コードで動的に変更できます。

新しいゲームプレイ タグを作成し、レベルにあるパズルのすべてのライトに割り当てるには、次のステップに従います。

1. Verse Explorer を開き、「tagged_lights_puzzle.verse」をダブルクリックして Visual Studio Code でそのスクリプトを開きます。

2. コード ファイルの先頭で以下を実行します。

   • using { /Verse.org/Simulation/Tags } を追加し、tag クラスを参照し、GetCreativeObjectsWithTag() 関数を使用します。

   • using { /Verse.org/Simulation } を追加し、編集可能なプロパティを作成できるようにします。

     Verse

           using { /Fortnite.com/Devices }
           using { /Verse.org/Native }
           using { /UnrealEngine.com/Temporary/Diagnostics }
           using { /Verse.org/Simulation/Tags }
           using { /Verse.org/Simulation }
     								    
           log_tagged_lights_puzzle := class(log_channel){}
     

     Copy full snippet(7 lines long)

3. log_tagged_lights_puzzle クラスの上で、tag クラスから継承した、puzzle_light と名付けた新しいサブクラスを追加します。 継承されたクラス名は、クリエイティブの仕掛けで使用するカスタム ゲームプレイ タグになります。

   Verse

        # Derive from the `tag` class in the Verse.org/Simulation/Tags module to create a new Gameplay Tag.
        puzzle_light := class(tag){}
   		
        log_tagged_lights_puzzle := class(log_channel){}
   

   Copy full snippet(4 lines long)

4. UEFN ツールバーの [Build Verse Scripts (Verse スクリプトをビルド)] をクリックして、コードと新しい puzzle_light ゲームプレイ タグをプロジェクトにコンパイルします。

5. UEFN の アウトライナー で カスタマイズ可能なライトの仕掛け を選択すると、[Details] パネルが開きます。

6. [Details] パネルで以下を行います。

   1. [Add New Component (新しいコンポーネントを追加)] をクリックして、[Verse Tag Markup] を選択します。

   2. VerseTagMarkup コンポーネントを選択して、[Details] パネルにその設定項目を表示します。

   3. [Gameplay Tags (ゲームプレイ タグ)] 内にある Tags プロパティを編集し、puzzle_light タグを追加します。

      

      複数のタグを同一の仕掛けに追加できます。つまりそれぞれの仕掛けは同時に複数のグループに所属できます。 たとえば、tag1 と tag2 が付いた仕掛けは、GetCreativeObjectsWithTag(tag1{}) または GetCreativeObjectsWithTag(tag2{}) を呼び出すときに見つかります。

7. tagged_lights_puzzle クラスの定義に次の 2 つの変数配列フィールドを追加します。

   • LightsState という編集可能な logic 変数配列、全ライトの現在のステート (オフまたはオン) を表します。 ライトの初期ステートを設定するためにも使用されます。つまり要素の数は、puzzle_light タグが付いたライト数と一致する必要があります。 この例では、すべてのライトはデフォルトでオフになっていて、すべてのライトの初期値は false です。

     Verse

           @editable
           var LightsState : []logic = array{false, false, false, false}
     

     Copy full snippet(2 lines long)

   • Lights という、編集可能な customizable_light_device 変数配列、puzzle_light ゲームプレイ タグが付いたカスタマイズ可能なライトの仕掛けをすべて格納します。

     Verse

           @editable
           var Lights : []customizable_light_device = array{}
     

     Copy full snippet(2 lines long)

8. ゲームを開始したとき、LightsState 配列で指定した初期コンフィギュレーションに一致するように、仕掛けがライトをセットアップし、Lights 配列に参照を保存します。つまりゲーム ステート が変わったときに更新できます。 この処理は SetupPuzzleLights() : void メソッドで実行され、OnBegin() メソッドで呼び出されます。その結果、ゲームを開始したときにライトがセットアップされます。

   Verse

        SetupPuzzleLights() : void =
            Logger.Print("Setting up in-game lights")
   
        OnBegin<override>()<suspends> : void =
            SetupPuzzleLights()

   Copy full snippet(5 lines long)

9. SetupPuzzleLights() で、GetCreativeObjectsWithTag(puzzle_light{}) を呼び出すことで puzzle_light タグが付いたすべての仕掛けを見つけ、TaggedActors という配列にそれらを保存します。 TaggedActors は定数配列で、そのスコープがメソッド SetupPuzzleLights() のローカルに限定されています。つまりこの状況で推測できるため、配列の型を明示的に指定する必要がありません。

   Verse

        SetupPuzzleLights() : void =
            Logger.Print("Setting up in-game lights")
            TaggedActors := GetCreativeObjectsWithTag(puzzle_light{})
   

   Copy full snippet(3 lines long)

   GetCreativeObjectsWithTag() 関数を別に呼び出すと、仕掛けが異なる順序で配列の結果に配置される場合があります。これは、ゲームプレイ タグを使って仕掛けを取得する際には順序が決まっていないためです。

10. puzzle_light タグが付いたすべての仕掛けを集めたので、LightsState 配列で指定した初期ステートに各ライトが一致することを確認します。 for ループを使用して、すべてのタグ付き仕掛けでイテレートします。

    Verse

         for:
             ActorIndex -> TaggedActor : TaggedActors
         do:
             TaggedActor
    

    Copy full snippet(4 lines long)

11. 関数 GetCreativeObjectsWithTag() はタイプ creative_object_interface の配列を返します。 この例では、ライトのオンとオフを切り替えられるように、各 TaggedActor を customizable_light_device としてインタラクトします。

    • NewDeviceReference := device_type_to_cast_to[DeviceReference] 構文を使用して、クラスをサブクラスの 1 つに変換 (型変換) できます。ここで device_type_to_cast_to は目的の仕掛けタイプで、この例では customizable_light_device です。 仕掛けが目的とする型に変換できない場合 (仕掛けの型が異なる場合など)、型変換は失敗するため、これは失敗する可能性がある式です。

      Verse

            LightDevice := customizable_light_device[TaggedActor]
      

      Copy full snippet(1 line long)

      GetCreativeObjectsWithTag() 関数はアクタのさまざまなタイプを返すことができるため、その戻り型は []creative_object_interface です。この戻り型は、すべてのアクタが GetCreativeObjectsWithTag() によって返されるために実装する必要のある インターフェース です。 詳細については、「ゲームプレイ タグ」を参照してください。

    • for 式があると、失敗する可能性がある式をフィルタとして使用でき、for コード ブロックで使用できる新しい変数を作成できます。 この場合、前のステップで実行した、customizable_light_device への型変換をイテレーション式に追加します。

      Verse

            for:
                ActorIndex -> TaggedActor : TaggedActors
                LightDevice := customizable_light_device[TaggedActor]
            do:
                LightDevice
      

      Copy full snippet(5 lines long)

    • コード ブロック内の最後の式は、そのコード ブロックの結果です。 for 式は、配列の各イテレーションからコード ブロックの結果を返します。つまりこの for 式の結果は、puzzle_light タグが付いた customize_light_device 参照の配列です。 つまり、for 式の結果を使用して Lights 配列を直接更新できます。

      Verse

            set Lights = for:
                ActorIndex -> TaggedActor : TaggedActors
                LightDevice := customizable_light_device[TaggedActor]
            do:
                LightDevice
      

      Copy full snippet(5 lines long)

    • この for ループは、エディター内の初期の LightsState 設定と一致するように、ライトに対して TurnOn() / TurnOff() も呼び出す必要があります。 for 式は、現在のタグ付きの仕掛け (例の ActorIndex) を取得するために使用されるインデックスを返すことができます。ライトがオンかオフかを確認するために、インデックスを LightsState 配列に入れるために使用できます。

      Verse

            set Lights = for:
                ActorIndex -> TaggedActor : TaggedActors
                LightDevice := customizable_light_device[TaggedActor]
                ShouldLightBeOn:= LightsState[ActorIndex]
            do:
                LightDevice
      

      Copy full snippet(6 lines long)

    • 次に、TurnOn() / TurnOff() を、ShouldLightBeOn が true / false に応じて呼び出します。 if 式を使用して、条件 (特に失敗する可能性がある式) に基づいて、異なる式を実行できます。 この場合は、失敗する可能性がある式ではクエリ演算子 ? と IsLightOn を使用できます。ShouldLightBeOn が true の場合は成功し (つまりTurnOn() を呼び出し)、ShouldLightBeOn が false の場合は失敗 (つまり TurnOff() を呼び出し) します。

      Verse

            set Lights = for:
                ActorIndex -> TaggedActor : TaggedActors
                LightDevice := customizable_light_device[TaggedActor]
                ShouldLightBeOn := LightsState[ActorIndex]
            do:
                if (ShouldLightBeOn?) then LightDevice.TurnOn() else LightDevice.TurnOff()
                LightDevice
      

      Copy full snippet(7 lines long)

    • ライトのインデックスとその開始時の値は出力もしておくことをお勧めします。そうすることで、コードが期待どおりに動作していることを検証でき、レベルで表示されている内容と比較できます。

    • 文字列の中で {} を使用するとき、{} に囲まれた式は、最初に評価され、その値が文字列に追加されます。 つまり、文字列の中で if 式を使用して、条件に応じて値を追加できます。

      Verse

            set Lights = for:
                ActorIndex -> TaggedActor : TaggedActors
                LightDevice := customizable_light_device[ActorIndex]
                ShouldLightBeOn := LightsState[ActorIndex]
            do:
                Logger.Print("Adding Light at index {ActorIndex} with State:{if (ShouldLightBeOn?) then "On" else "Off"}")
                if (ShouldLightBeOn?) then LightDevice.TurnOn() else LightDevice.TurnOff()
                LightDevice
      

      Copy full snippet(8 lines long)

12. SetupPuzzleLights() メソッドは次のようになります。

    Verse

         SetupPuzzleLights() : void =
             TaggedActors := GetCreativeObjectsWithTag(puzzle_light{})
             <#
             For each device with the puzzle_light tag, check if it's a customizable_light_device by trying to cast it to that type.
             If it is, get its initial LightState to TurnOn() or TurnOff() the LightDevice.
             Save all the tagged customizable_light_device in the Lights array.
             #>
             set Lights = for:
                     ActorIndex -> TaggedActor : TaggedActors
                     LightDevice := customizable_light_device[TaggedActor]
    
    Expand code Copy full snippet(15 lines long)

13. Visual Studio Code にスクリプトを保存します。

14. UEFN ツールバーの [Build Verse Scripts (Verse スクリプトをビルド)] をクリックして、作成したコードをコンパイルします。

15. UEFN ツールバーの [Play (プレイ)] をクリックして、レベルをプレイテストします。

レベルをプレイテストするとき、Lights 配列に追加したそれぞれのライトが、初期状態に応じて、出力ログに出力されていることを確認します。

次のステップ

このチュートリアルの 次のステップ では、プレイヤーがボタンを押したときに、ライトの特定セットのオン/オフを切り替える方法について学びます。