1. Epic GamesDeveloper
  3. 5. 撃破で武器を付与する

5. 撃破で武器を付与する

Verse を使用して、一連の武器を順に使用してチームが勝ち進むマルチプレイヤー対戦ゲーム モードを作成します。

5. 撃破で武器を付与する
Prerequisite topics

In order to understand and use the content on this page, make sure you are familiar with the following topics:

マップの設定が完了しました。次のステップでは、プレイヤーが撃破を達成したときに武器を付与します。

プレイヤーが撃破を達成すると、次の 2 つのルールを適用します。

  1. プレイヤーの武器のティアがチームで最も高いティアではない場合、またはすべてのプレイヤーが同じ武器のティアにいる場合、次のティアに昇格します。

  2. チーム内に他より低い武器のティアにいるプレイヤーがいる場合は、代わりにそのプレイヤーを昇格させます。

これにより、プレイヤーはチームとして武器の切り替えを進めていき、チームメイトの誰も 2 つ以上先または後の武器を使用することがなくなります。

そのためには、プレイヤーがいつ撃破を達成したのかを把握し、次に武器のティアをチーム内にいる他のすべてのプレイヤーと比較して、上述の 2 つのルールに基づいてプレイヤーを昇格させる必要があります。

次の手順に従って、撃破を達成したプレイヤーに武器を付与します。

  1. 新しいメソッド GiveNextWeapon を team_elimination_game クラスに追加します。このメソッドは、プレイヤーまたは属するチーム内の誰かが撃破を達成するたびに、上述の 2 つのルールに基づいてプレイヤーに武器を付与します。

     GiveNextWeapon(EliminatingPlayer : agent) : void =
     Print("Finding a player to promote")

  2. OnPlayerEliminated を、どのプレイヤーが撃破を達成したかを追跡するように更新します。OnPlayerEliminated は elimination_result を受け取るため、撃破されたキャラクターと撃破したキャラクターの両方への参照を取得できます。プレイヤーはさまざまな方法 (落下ダメージ、セントリー、自己ダメージなど) で撃破される可能性があるため、EliminatingCharacter が実際の FortCharacter (つまり実際のプレイヤー) であるかどうかを推定する必要があります。

    • Result.EliminatingCharacter への参照を取得し、ローカル オプション変数 Eliminator に格納します。Eliminator が有効な FortCharacter であるかどうかをチェックし、有効であればそのキャラクターのエージェントを別の変数 EliminatorAgent に格納します。最後に、EliminatorAgent を GiveNextWeapon に渡します。
     OnPlayerEliminated(Result : elimination_result) : void =
     Print("A Player was eliminated!")
     Eliminator := Result.EliminatingCharacter
     if (FortCharacter := Eliminator?, EliminatorAgent := FortCharacter.GetAgent[]):
         GiveNextWeapon(EliminatorAgent)

  3. GiveNextWeapon では、適切なプレイヤーに新しい武器を付与するためにいくつかの変数を追跡する必要があります。次の宣言を GiveNextWeapon に追加します。

    • int 変数 WeaponTier。これは、武器を付与するプレイヤーの武器のティアを追跡します。

    • MaybePlayerToGrant という名前の任意指定の agent 変数。これは、武器を付与するプレイヤーです。これはデフォルトでは、GiveNextWeapon に渡されたプレイヤーです。

    • MaybePlayerTeam という名前の任意指定の team 変数。これは武器を付与するプレイヤーのチームです。これはデフォルトでは、GiveNextWeapon に渡されたプレイヤーのチームです。

     GiveNextWeapon(EliminatingPlayer : agent) : void =
     Print("Finding a player to promote")
     var WeaponTier : int = 0
     var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # The player to grant a gun to
     var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # The team this player is on

  4. MaybePlayerTeam の値をローカル変数 PlayerTeam に抽出し、次に WeaponTier を、TeamMap にあるそのプレイヤーのスコアの値に設定します。

     var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # The team this player is on
     if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):

  5. そのチームのプレイヤーごとにイテレートし、それぞれの武器のティアを比較します。低いティアのプレイヤーがいた場合、MaybePlayerToGrant をそのプレイヤーに、WeaponTier をそのプレイヤーのスコアに設定します。TeamMap はマップであるため、Teammate -> TeammateTier 構文を使用して、キー (プレイヤー) と値 (武器のティア) の両方をローカル変数として抽出できます。

     if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
     for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
         Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
         if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
             set MaybePlayerToGrant = option{Teammate}

  6. 武器のティアが最も低い (または最も低いティアと同じ) プレイヤーが見つかったら、WeaponTier を 1 だけ増やしてから、TeamMap 内のそのプレイヤーの武器のティアを WeaponTier に設定します。

     if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
     for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
         Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
         if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
             set MaybePlayerToGrant = option{Teammate}

 set WeaponTier = WeaponTier + 1
 if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
     Print("Eliminating Player Tier is now {WeaponTier}")

  7. 武器のティアを昇格するとゲームを終了するために必要な撃破数を超えることがあるため、ここでプレイヤーがゲームに勝利したかどうかを確認することをお勧めします。

    • 新しいメソッド EndGame を team_elimination_game クラス内に作成します。このメソッドは、指定されたプレイヤーが最終的な武器のティアに到達したときに、そのプレイヤーに対して EndGameDevice をアクティブ化します。完成したメソッドは次のようになっているはずです。
     EndGame(InPlayer : agent) : void =
     Print("Player reached final Weapon Tier, activating EndGameDevice")
     EndGameDevice.Activate(InPlayer)
    • GiveNextWeapon に戻り、プレイヤーの武器のティアを増やした後に、WeaponTier >= EliminationsToEndGame であるかどうかをチェックします。この条件を満たしている場合は、プレイヤーを渡して EndGame を呼び出します。
     if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
     Print("Eliminating Player Tier is now {WeaponTier}")

 if(WeaponTier >= EliminationsToEndGame):
     EndGame(EliminatingPlayer)

  8. この条件を満たしていない場合は、GrantedPlayer に対して GrantWeapon を呼び出します。

     if(WeaponTier >= EliminationsToEndGame):
     EndGame(EliminatingPlayer)

 GrantWeapon(MaybePlayerToGrant, WeaponTier)

  9. 完成した GiveNextWeapon メソッドのコードは次のようになっているはずです。

     GiveNextWeapon(EliminatingPlayer : agent) : void =
     Print("Finding a player to promote")
     var WeaponTier : int = 0
     var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # 銃を付与するプレイヤー
     var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # このプレイヤーが属するチーム
     if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
         for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
             Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
             if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
                 set MaybePlayerToGrant = option{Teammate}

     set WeaponTier = WeaponTier + 1
     if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
         Print("Eliminating Player Tier is now {WeaponTier}")

     if(WeaponTier >= EliminationsToEndGame):
         EndGame(EliminatingPlayer)

     GrantWeapon(MaybePlayerToGrant, WeaponTier)

Visual Studio Code でスクリプトを保存してコンパイルし、UEFN ツールバーの [Launch Session (セッションを起動)] をクリックしてレベルをプレイテストします。レベルをプレイテストするときは、WeaponGranters 配列の最初の武器をもう一度スポーンする必要があります。この動作をログで確認してくださいしてください。敵プレイヤーへの撃破が成功すると、次の武器に昇格します。昇格は、先ほど概説した 2 つのルールに従う必要があります。シーケンスの最終武器まで昇格して撃破すると、撃破したプレイヤーが勝者となってゲームが終了します。

Granting Weapons on Elimination

次のステップ

このチュートリアルの 次のステップ では、進行中のゲームに参加するプレイヤーをマップに追加し、武器を割り当てる方法について学びます。

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page