チーム撃破 8 Verse での最終結果 | Fortnite ドキュメンテーション

完全なスクリプト

次のコードは、プレイヤーがチームとして一連の武器を順に使用して勝ち進む撃破ゲームの完全なスクリプトです。

using { /Fortnite.com/Characters}
using { /Fortnite.com/Devices}
using { /Fortnite.com/Game}
using { /Fortnite.com/Teams}
using { /Verse.org/Simulation}


player_map := [player]int # This is a type alias!

team_elimination_game := class(creative_device):

    @editable
    EndGameDevice : end_game_device = end_game_device{}

    @editable
    var WeaponGranters : []item_granter_device = array{}

    @editable
    var PlayerSpawners : []player_spawner_device = array{}

    @editable
    var Sentries : []sentry_device = array{}

    var EliminationsToEndGame : int = 0

    var Teams:[]team = array{}

    # チーム マップのマップ。キーはチームであり、値は
    # player->int のキー/値のペアのマップです。
    var TeamMap : [team]player_map = map{}  

    OnBegin<override>()<suspends> : void =
        set Teams = GetPlayspace().GetTeamCollection().GetTeams()
        set EliminationsToEndGame = WeaponGranters.Length
        Print("Beginning to assign players")

        PopulateTeamsAndPlayers()   

        for (Spawner : PlayerSpawners):
            Spawner.SpawnedEvent.Subscribe(OnPlayerSpawn) # 各プレイヤー スポーン パッドにサブスクライブします

        for (Sentry : Sentries):
            Sentry.EliminatedEvent.Subscribe(TestPlayerEliminated) # 各セントリーにサブスクライブします

        # ゲームに参加した新しいプレイヤーにサブスクライブします。

        GetPlayspace().PlayerAddedEvent().Subscribe(OnPlayerAdded)

    PopulateTeamsAndPlayers() : void =
        Print("Beginning to populate players")
        for (Team : Teams, TeamPlayers := GetPlayspace().GetTeamCollection().GetAgents[Team]):
            var PlayerMap : player_map = map {}
            for (Agent : TeamPlayers, TeamPlayer := player[Agent], FortCharacter := Agent.GetFortCharacter[]): 
                if(set PlayerMap[TeamPlayer] = 0, WeaponTier := PlayerMap[TeamPlayer]): 
                    Print("Assigned Player to PlayerMap with Tier {WeaponTier}")
                FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) 
            if(set TeamMap[Team] = PlayerMap):
                Print("Successfully set this team in the TeamMap")

    # ゲームに参加した新しいプレイヤーを処理します。

    OnPlayerAdded(InPlayer : player) : void =
        Print("A New Player Joined!")
        if:
            Team := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            FortCharacter := InPlayer.GetFortCharacter[]
            var PlayerMap : player_map = TeamMap[Team]
            set PlayerMap[InPlayer] = 0
            set TeamMap[Team] = PlayerMap
        then:
            GrantWeapon(option{InPlayer}, 0)
            Print("Set new player weapon tier to 0 in the TeamMap")
            FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) # このプレイヤーの撃破イベントにサブスクライブします

    # プレイヤーのスポーン時に、そのプレイヤーの WeaponTier に基づいて武器を付与します。

    OnPlayerSpawn(InPlayer : agent) : void =
        Print("A player just spawned!")
        if:
            PlayerTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            WeaponTier:int := TeamMap[PlayerTeam][InPlayer]
        then:
            GrantWeapon(option{InPlayer}, WeaponTier)
            Print("Spawned Player was granted a gun of tier {WeaponTier}")

    OnPlayerEliminated(Result : elimination_result) : void =
        Print("A Player was eliminated!")
        Eliminator := Result.EliminatingCharacter
        if (FortCharacter := Eliminator?, EliminatorAgent := FortCharacter.GetAgent[]):
            GiveNextWeapon(EliminatorAgent)

    # セントリーがプレイヤーになりすますことによって、GiveNextWeapon をテストできるようにします。

    TestPlayerEliminated(Agent: ?agent) : void =
        Print("Sentry Down!")
        if(TeamPlayer := Agent?):
            GiveNextWeapon(TeamPlayer)

    GiveNextWeapon(EliminatingPlayer : agent) : void =
        Print("Finding a player to promote")
        var WeaponTier : int = 0
        var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # The player to grant a gun to
        var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # The team this player is on

        if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
            for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
                Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
                if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
                    set MaybePlayerToGrant = option{Teammate}

        set WeaponTier = WeaponTier + 1
        if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
            Print("Eliminating Player Tier is now {WeaponTier}")

        if(WeaponTier >= EliminationsToEndGame):
            EndGame(EliminatingPlayer)

        GrantWeapon(MaybePlayerToGrant, WeaponTier)
        
    GrantWeapon(InPlayer : ?agent,WeaponTier : int) : void =
        Print("Promoting Player to Tier {WeaponTier}")
        if(ItemGranter := WeaponGranters[WeaponTier], GrantedPlayer := InPlayer?):
            ItemGranter.GrantItem(GrantedPlayer)

    EndGame(InPlayer : agent) : void =
        Print("Player reached final Weapon Tier, activating EndGameDevice")
        EndGameDevice.Activate(InPlayer)

using { /Fortnite.com/Characters}
using { /Fortnite.com/Devices}
using { /Fortnite.com/Game}
using { /Fortnite.com/Teams}
using { /Verse.org/Simulation}

player_map := [player]int # This is a type alias!

team_elimination_game := class(creative_device):

@editable
    EndGameDevice : end_game_device = end_game_device{}

@editable
    var WeaponGranters : []item_granter_device = array{}

@editable
    var PlayerSpawners : []player_spawner_device = array{}

@editable
    var Sentries : []sentry_device = array{}

var EliminationsToEndGame : int = 0

var Teams:[]team = array{}

# チーム マップのマップ。キーはチームであり、値は
    # player->int のキー/値のペアのマップです。
    var TeamMap : [team]player_map = map{}

OnBegin<override>()<suspends> : void =
        set Teams = GetPlayspace().GetTeamCollection().GetTeams()
        set EliminationsToEndGame = WeaponGranters.Length
        Print("Beginning to assign players")

PopulateTeamsAndPlayers()

for (Spawner : PlayerSpawners):
            Spawner.SpawnedEvent.Subscribe(OnPlayerSpawn) # 各プレイヤー スポーン パッドにサブスクライブします

for (Sentry : Sentries):
            Sentry.EliminatedEvent.Subscribe(TestPlayerEliminated) # 各セントリーにサブスクライブします

# ゲームに参加した新しいプレイヤーにサブスクライブします。

GetPlayspace().PlayerAddedEvent().Subscribe(OnPlayerAdded)

PopulateTeamsAndPlayers() : void =
        Print("Beginning to populate players")
        for (Team : Teams, TeamPlayers := GetPlayspace().GetTeamCollection().GetAgents[Team]):
            var PlayerMap : player_map = map {}
            for (Agent : TeamPlayers, TeamPlayer := player[Agent], FortCharacter := Agent.GetFortCharacter[]): 
                if(set PlayerMap[TeamPlayer] = 0, WeaponTier := PlayerMap[TeamPlayer]): 
                    Print("Assigned Player to PlayerMap with Tier {WeaponTier}")
                FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) 
            if(set TeamMap[Team] = PlayerMap):
                Print("Successfully set this team in the TeamMap")

# ゲームに参加した新しいプレイヤーを処理します。

OnPlayerAdded(InPlayer : player) : void =
        Print("A New Player Joined!")
        if:
            Team := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            FortCharacter := InPlayer.GetFortCharacter[]
            var PlayerMap : player_map = TeamMap[Team]
            set PlayerMap[InPlayer] = 0
            set TeamMap[Team] = PlayerMap
        then:
            GrantWeapon(option{InPlayer}, 0)
            Print("Set new player weapon tier to 0 in the TeamMap")
            FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) # このプレイヤーの撃破イベントにサブスクライブします

# プレイヤーのスポーン時に、そのプレイヤーの WeaponTier に基づいて武器を付与します。

OnPlayerSpawn(InPlayer : agent) : void =
        Print("A player just spawned!")
        if:
            PlayerTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            WeaponTier:int := TeamMap[PlayerTeam][InPlayer]
        then:
            GrantWeapon(option{InPlayer}, WeaponTier)
            Print("Spawned Player was granted a gun of tier {WeaponTier}")

OnPlayerEliminated(Result : elimination_result) : void =
        Print("A Player was eliminated!")
        Eliminator := Result.EliminatingCharacter
        if (FortCharacter := Eliminator?, EliminatorAgent := FortCharacter.GetAgent[]):
            GiveNextWeapon(EliminatorAgent)

# セントリーがプレイヤーになりすますことによって、GiveNextWeapon をテストできるようにします。

TestPlayerEliminated(Agent: ?agent) : void =
        Print("Sentry Down!")
        if(TeamPlayer := Agent?):
            GiveNextWeapon(TeamPlayer)

GiveNextWeapon(EliminatingPlayer : agent) : void =
        Print("Finding a player to promote")
        var WeaponTier : int = 0
        var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # The player to grant a gun to
        var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # The team this player is on

if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
            for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
                Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
                if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
                    set MaybePlayerToGrant = option{Teammate}

set WeaponTier = WeaponTier + 1
        if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
            Print("Eliminating Player Tier is now {WeaponTier}")

if(WeaponTier >= EliminationsToEndGame):
            EndGame(EliminatingPlayer)

GrantWeapon(MaybePlayerToGrant, WeaponTier)
        
    GrantWeapon(InPlayer : ?agent,WeaponTier : int) : void =
        Print("Promoting Player to Tier {WeaponTier}")
        if(ItemGranter := WeaponGranters[WeaponTier], GrantedPlayer := InPlayer?):
            ItemGranter.GrantItem(GrantedPlayer)

EndGame(InPlayer : agent) : void =
        Print("Player reached final Weapon Tier, activating EndGameDevice")
        EndGameDevice.Activate(InPlayer)

応用編

このガイドを完了したことで、Verse を使用して仕掛けを作成する方法を習得しました。プレイヤーやチームメイトには撃破するたびに次の武器が付与され、一連の武器を順番に使用して進んでいきます。

このガイドで学習した知識を活用し、次のことを実行してみましょう。

武器の順序や組み合わせをいろいろと試して、最適なプレイ体験を作り出す。
セントリーを配置し、各チームの任意のボスとして使用することを検討する。
チームの特定のプレイヤー 1 人を撃破するなど、得点獲得のためのさまざまなメソッドを探してみる。