Jeu d'élimination par équipe 8 Résultat final dans Verse | Fortnite Documentation

Script complet

Le code suivant constitue le script complet du jeu d’élimination qui fait avancer les joueurs grâce à une série d’armes.

using { /Fortnite.com/Characters }
using { /Fortnite.com/Devices }
using { /Fortnite.com/Game }
using { /Fortnite.com/Teams }
using { /Verse.org/Simulation } }


player_map := [player]int # This is a type alias!

team_elimination_game := class(creative_device):

    @editable
    EndGameDevice : end_game_device = end_game_device{}

    @editable
    var WeaponGranters : []item_granter_device = array{}

    @editable
    var PlayerSpawners : []player_spawner_device = array{}

    @editable
    var Sentries : []sentry_device = array{}

    var EliminationsToEndGame : int = 0

    var Teams : []team = array{}

    # Carte des cartes d’équipes, où la clé est l'équipe et la valeur est une carte de
    # joueurs->paires clés/valeurs int
    var TeamMap : [team]player_map = map{}  

    OnBegin<override>()<suspends> : void =
        set Teams = GetPlayspace().GetTeamCollection().GetTeams()
        set EliminationsToEndGame = WeaponGranters.Length
        Print("Beginning to assign players")

        PopulateTeamsAndPlayers()   

        for (Spawner : PlayerSpawners):
            Spawner.SpawnedEvent.Subscribe(OnPlayerSpawn) # S'abonner à chaque point d'apparition de joueur

        for (Sentry : Sentries):
            Sentry.EliminatedEvent.Subscribe(TestPlayerEliminated) # S'abonner à chaque sentinelle

        # S'abonner aux nouveaux joueurs qui rejoignent la partie

        GetPlayspace().PlayerAddedEvent().Subscribe(OnPlayerAdded)

    PopulateTeamsAndPlayers() : void =
        Print("Beginning to populate players")
        for (Team : Teams, TeamPlayers := GetPlayspace().GetTeamCollection().GetAgents[Team]):
            var PlayerMap : player_map = map {}
            for (Agent : TeamPlayers, TeamPlayer := player[Agent], FortCharacter := Agent.GetFortCharacter[]): 
                if(set PlayerMap[TeamPlayer] = 0, WeaponTier := PlayerMap[TeamPlayer]): 
                    Print("Assigned Player to PlayerMap with Tier {WeaponTier}")
                FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) 
            if(set TeamMap[Team] = PlayerMap):
                Print("Successfully set this team in the TeamMap")

    # Gère un nouveau joueur qui rejoint la partie

    OnPlayerAdded(InPlayer : player) : void =
        Print("A New Player Joined!")
        if:
            Team := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            FortCharacter := InPlayer.GetFortCharacter[]
            var PlayerMap : player_map = TeamMap[Team]
            set PlayerMap[InPlayer] = 0
            set TeamMap[Team] = PlayerMap
        then:
            GrantWeapon(option{InPlayer}, 0)
            Print("Set new player weapon tier to 0 in the TeamMap")
            FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) # subscribe to this player's elimination event

    # Accorde aux joueurs des armes en fonction de leur niveau d’armement lorsqu'ils apparaissent

    OnPlayerSpawn(InPlayer : agent) : void =
        Print("A player just spawned!")
        if:
            PlayerTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            WeaponTier:int := TeamMap[PlayerTeam][InPlayer]
        then:
            GrantWeapon(option{InPlayer}, WeaponTier)
            Print("Spawned Player was granted a gun of tier {WeaponTier}")

    OnPlayerEliminated(Result : elimination_result) : void =
        Print("A Player was eliminated!")
        Eliminator := Result.EliminatingCharacter
        if (FortCharacter := Eliminator?, EliminatorAgent := FortCharacter.GetAgent[]):
            GiveNextWeapon(EliminatorAgent)

    # Permet de tester GiveNextWeapon en faisant passer les sentinelles pour des joueurs.

    TestPlayerEliminated(Agent: ?agent) : void =
        Print("Sentry Down!")
        if(TeamPlayer := Agent?):
            GiveNextWeapon(TeamPlayer)

    GiveNextWeapon(EliminatingPlayer : agent) : void =
        Print("Finding a player to promote")
        var WeaponTier : int = 0
        var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # The player to grant a gun to
        var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # The team this player is on

        if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
            for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
                Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
                if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
                    set MaybePlayerToGrant = option{Teammate}

        set WeaponTier = WeaponTier + 1
        if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
            Print("Eliminating Player Tier is now {WeaponTier}")

        if(WeaponTier >= EliminationsToEndGame):
            EndGame(EliminatingPlayer)

        GrantWeapon(MaybePlayerToGrant, WeaponTier)
        
    GrantWeapon(InPlayer : ?agent, WeaponTier : int) : void =
        Print("Promoting Player to Tier {WeaponTier}")
        if(ItemGranter := WeaponGranters[WeaponTier], GrantedPlayer := InPlayer?):
            ItemGranter.GrantItem(GrantedPlayer)

    EndGame(InPlayer : agent) : void =
        Print("Player reached final Weapon Tier, activating EndGameDevice")
        EndGameDevice.Activate(InPlayer)

using { /Fortnite.com/Characters }
using { /Fortnite.com/Devices }
using { /Fortnite.com/Game }
using { /Fortnite.com/Teams }
using { /Verse.org/Simulation } }

player_map := [player]int # This is a type alias!

team_elimination_game := class(creative_device):

@editable
    EndGameDevice : end_game_device = end_game_device{}

@editable
    var WeaponGranters : []item_granter_device = array{}

@editable
    var PlayerSpawners : []player_spawner_device = array{}

@editable
    var Sentries : []sentry_device = array{}

var EliminationsToEndGame : int = 0

var Teams : []team = array{}

# Carte des cartes d’équipes, où la clé est l'équipe et la valeur est une carte de
    # joueurs->paires clés/valeurs int
    var TeamMap : [team]player_map = map{}

OnBegin<override>()<suspends> : void =
        set Teams = GetPlayspace().GetTeamCollection().GetTeams()
        set EliminationsToEndGame = WeaponGranters.Length
        Print("Beginning to assign players")

PopulateTeamsAndPlayers()

for (Spawner : PlayerSpawners):
            Spawner.SpawnedEvent.Subscribe(OnPlayerSpawn) # S'abonner à chaque point d'apparition de joueur

for (Sentry : Sentries):
            Sentry.EliminatedEvent.Subscribe(TestPlayerEliminated) # S'abonner à chaque sentinelle

# S'abonner aux nouveaux joueurs qui rejoignent la partie

GetPlayspace().PlayerAddedEvent().Subscribe(OnPlayerAdded)

PopulateTeamsAndPlayers() : void =
        Print("Beginning to populate players")
        for (Team : Teams, TeamPlayers := GetPlayspace().GetTeamCollection().GetAgents[Team]):
            var PlayerMap : player_map = map {}
            for (Agent : TeamPlayers, TeamPlayer := player[Agent], FortCharacter := Agent.GetFortCharacter[]): 
                if(set PlayerMap[TeamPlayer] = 0, WeaponTier := PlayerMap[TeamPlayer]): 
                    Print("Assigned Player to PlayerMap with Tier {WeaponTier}")
                FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) 
            if(set TeamMap[Team] = PlayerMap):
                Print("Successfully set this team in the TeamMap")

# Gère un nouveau joueur qui rejoint la partie

OnPlayerAdded(InPlayer : player) : void =
        Print("A New Player Joined!")
        if:
            Team := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            FortCharacter := InPlayer.GetFortCharacter[]
            var PlayerMap : player_map = TeamMap[Team]
            set PlayerMap[InPlayer] = 0
            set TeamMap[Team] = PlayerMap
        then:
            GrantWeapon(option{InPlayer}, 0)
            Print("Set new player weapon tier to 0 in the TeamMap")
            FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) # subscribe to this player's elimination event

# Accorde aux joueurs des armes en fonction de leur niveau d’armement lorsqu'ils apparaissent

OnPlayerSpawn(InPlayer : agent) : void =
        Print("A player just spawned!")
        if:
            PlayerTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]
            WeaponTier:int := TeamMap[PlayerTeam][InPlayer]
        then:
            GrantWeapon(option{InPlayer}, WeaponTier)
            Print("Spawned Player was granted a gun of tier {WeaponTier}")

OnPlayerEliminated(Result : elimination_result) : void =
        Print("A Player was eliminated!")
        Eliminator := Result.EliminatingCharacter
        if (FortCharacter := Eliminator?, EliminatorAgent := FortCharacter.GetAgent[]):
            GiveNextWeapon(EliminatorAgent)

# Permet de tester GiveNextWeapon en faisant passer les sentinelles pour des joueurs.

TestPlayerEliminated(Agent: ?agent) : void =
        Print("Sentry Down!")
        if(TeamPlayer := Agent?):
            GiveNextWeapon(TeamPlayer)

GiveNextWeapon(EliminatingPlayer : agent) : void =
        Print("Finding a player to promote")
        var WeaponTier : int = 0
        var MaybePlayerToGrant : ?agent = option{EliminatingPlayer} # The player to grant a gun to
        var MaybePlayerTeam : ?team = option{GetPlayspace().GetTeamCollection().GetTeam[EliminatingPlayer]} # The team this player is on

if(PlayerTeam := MaybePlayerTeam?, set WeaponTier = TeamMap[PlayerTeam][EliminatingPlayer]):
            for(Teammate -> TeammateTier : TeamMap[PlayerTeam], TeammateTier < WeaponTier):
                Print("Found a Teammate with a lower Tier at Tier {TeammateTier}")
                if(set WeaponTier = TeamMap[PlayerTeam][Teammate]):
                    set MaybePlayerToGrant = option{Teammate}

set WeaponTier = WeaponTier + 1
        if(PlayerTeam := MaybePlayerTeam?, PlayerToGrant := player[MaybePlayerToGrant?], set TeamMap[PlayerTeam][PlayerToGrant] = WeaponTier):
            Print("Eliminating Player Tier is now {WeaponTier}")

if(WeaponTier >= EliminationsToEndGame):
            EndGame(EliminatingPlayer)

GrantWeapon(MaybePlayerToGrant, WeaponTier)
        
    GrantWeapon(InPlayer : ?agent, WeaponTier : int) : void =
        Print("Promoting Player to Tier {WeaponTier}")
        if(ItemGranter := WeaponGranters[WeaponTier], GrantedPlayer := InPlayer?):
            ItemGranter.GrantItem(GrantedPlayer)

EndGame(InPlayer : agent) : void =
        Print("Player reached final Weapon Tier, activating EndGameDevice")
        EndGameDevice.Activate(InPlayer)

À vous de jouer

Grâce à ce tutoriel, vous avez appris à créer un appareil avec Verse qui fait avancer les joueurs à l’aide d’une série d’armes et où chaque élimination leur accorde, à eux ou à leurs coéquipiers, l'arme suivante.

Utilisez vos connaissances pour effectuer les tâches suivantes :

Essayer différents ordres et combinaisons d'armes pour créer une expérience de jeu optimale.
Envisager de conserver les sentinelles et de les utiliser comme responsables d’équipe.
Rechercher différentes méthodes pour marquer des points, par exemple en éliminant un joueur particulier d'une équipe.