1. Epic GamesDeveloper
  3. 4. Dönen Nesneler

4. Dönen Nesneler

Fall Guys parkurundaki engelleri nasıl döndüreceğini öğren.

4. Dönen Nesneler

Bu türe özgü bir başka platform engeli de, sürekli olarak hareket etmen gereken dönen bir platform veya üzerinden atlaman gereken ileri geri hareket eden bir çubuk gibi dönen objelerdir.

Bir obje dönüşümünün ikinci bileşeni onun dönüşüdür ve objeyi bir eksen etrafında dönecek şekilde değiştirebilirsin. Benzersiz platform zorlukları oluşturmak için dönüşü kullanmanın birkaç farklı yolu vardır ve bu bölümde bunları nasıl kodlayacağını öğreneceksin.

Dönen Nesneler Yapma

Nesneleri döndüren kodu oluşturmak için şu adımları izle:

  1. Verse Gezgini ile movable_prop öğesinden devralınan rotating_prop adında yeni bir Verse sınıfı oluştur. Özelliklerini UEFN’de kullanıma açmak için bu sınıfa <concrete> ekle.

     # Ek bir dönüş yaparak dönen veya kreatif nesnesi dönüşü ile eşleşecek
 # şekilde dönen bir nesne.
 rotating_prop<public> := class<concrete>(movable_prop):

  2. using { /Fortnite.com/Devices/CreativeAnimation } ve using { /UnrealEngine.com/Temporary/SpatialMath } ifadelerini dosyanın üst kısmına ekleyerek bu modülleri içe aktar. Nesnene animasyon uygulamak için bunlara ihtiyacın var. Ayrıca bu bölümde kullanılan araç ipuçlarına burada yer verilmiştir.

     using { /Fortnite.com/Devices }
 using { /Fortnite.com/Devices/CreativeAnimation }
 using { /Verse.org/Simulation }
 using { /UnrealEngine.com/Temporary/SpatialMath }

 AdditionalRotationTip<localizes>:message = "RootProp’a uygulanacak dönüş."
 ShouldRotateForeverTip<localizes>:message = "RootProp’un her zaman dönmesi gerekip gerekmediğini gösterir."
 MatchRotationTargetTip<localizes>:message = "Dönüşü RootProp dönüşüyle aynı olması gereken isteğe bağlı nesne. Bir Ek Dönüş ayarlamak istemezsen bunu kullan."

 # Ek bir dönüş yaparak dönen veya kreatif nesnesi dönüşü ile eşleşecek
 # şekilde dönen bir nesne.
 rotating_prop<public> := class<concrete>(movable_prop):
  3. rotating_prop sınıf tanımının üst kısmına aşağıdaki alanları ekle.

    1. AdditionalRotation adında düzenlenebilir bir rotation. Nesneye uygulanacak dönüştür. Move() tamamlandıktan sonra, nesne dönüşü bu değerde ofsetlenir.

       # RootProp’a uygulanacak ek dönüş.
 @editable {ToolTip := AdditionalRotationTip}
 AdditionalRotation:rotation = rotation{}

    2. ShouldRotateForever adlı bir düzenlenebilir logic. Nesnenin sıfırlanmadan dönmeye devam edip etmeyeceğini belirtir.

       # RootProp’un sonsuza dek dönüp dönmeyeceğini gösterir.
 @editable {ToolTip := ShouldRotateForeverTip}
 ShouldRotateForever:logic = true

    3. MatchRotationTarget adlı bir düzenlenebilir isteğe bağlı creative_prop. Nesnenin başka bir nesne dönüşüyle eşleşecek şekilde dönmesini istiyorsan AdditionalRotation özelliğini kullanmak yerine bu değeri ayarlayabilirsin.

       # Dönüşü RootProp dönüşüyle eşleşmesi gereken isteğe bağlı nesne. Bunu kullanmak için
 # ek bir dönüş ayarlamak istemiyor olman gerekir.
 @editable {ToolTip := MatchRotationTargetTip}
 MatchRotationTarget:?creative_prop = false

    4. TargetRotation adında bir rotation değişkeni. Bu, nesnenin halihazırda dönme işlemini gerçekleştirdiği dönüş yönüdür.

       # Nesnenin halihazırda dönme işlemini gerçekleştirdiği dönüş yönüdür.
 var TargetRotation:rotation = rotation{}

  4. Son sınıf tanımın şu şekilde görünmelidir:

     using { /Fortnite.com/Devices }
 using { /Fortnite.com/Devices/CreativeAnimation }
 using { /Verse.org/Simulation }
 using { /UnrealEngine.com/Temporary/SpatialMath }

 AdditionalRotationTip<localizes>:message = "RootProp’a uygulanacak dönüş."
 ShouldRotateForeverTip<localizes>:message = "RootProp’un her zaman dönmesi gerekip gerekmediğini gösterir."
 MatchRotationTargetTip<localizes>:message = "Dönüşü RootProp dönüşüyle aynı olması gereken isteğe bağlı nesne. Bir Ek Dönüş ayarlamak istemezsen bunu kullan."

 # Ek bir dönüş yaparak dönen veya kreatif nesnesi dönüşü ile eşleşecek
 # şekilde dönen bir nesne.
 rotating_prop<public> := class<concrete>(movable_prop):
    
     # RootProp’a uygulanacak ek dönüş.
     @editable {ToolTip := AdditionalRotationTip}
     AdditionalRotation:rotation = rotation{}

     # RootProp’un sonsuza dek dönüp dönmeyeceğini gösterir.
     @editable {ToolTip := ShouldRotateForeverTip}
     ShouldRotateForever:logic = true

     # Dönüşü RootProp dönüşüyle eşleşmesi gereken isteğe bağlı nesne. Bunu kullanmak için
     # ek bir dönüş ayarlamak istemiyor olman gerekir.
     @editable {ToolTip := MatchRotationTargetTip}
     MatchRotationTarget:?creative_prop = false

     # Nesnenin halihazırda dönme işlemini gerçekleştirdiği dönüş yönüdür.
     var TargetRotation:rotation = rotation{}

  5. Nesneni movable_prop öğesinde hareket ettiren Move() fonksiyonunu zaten ayarladığın için bu sınıfta geçersiz kılabilirsin. rotating_prop sınıfında Move() fonksiyonunu geçersiz kıl. Move()dayken öncelikle MatchRotationTarget ayarının yapılıp yapılmadığını kontrol et ve bir RotationToMatch değişkenine kaydet. İşlem gerçekleştirildiyse, TargetRotation öğesini RotationToMatch olarak ayarla. Aksi halde AdditionalRotation olarak ayarla.

     # RootProp’u TargetRotation uygulayarak veya ayarlanmışsa MovePosition öğesine doğru döndür.
 Move<override>()<suspends>:void=

     # MoveTarget ayarlanmışsa TargetRotation öğesini MoveTarget dönüşüne ayarla.
     if:
         RotationToMatch := MatchRotationTarget?.GetTransform().Rotation
     then:
         set TargetRotation = RotationToMatch
     else:
         set TargetRotation = AdditionalRotation
  6. Oynatılacak animasyonun için translating_prop bölümünde yaptığın gibi animasyon modunu belirle. AnimationMode adında yeni bir animation_mode değişkenini animation_mode.OneShot olarak başlat. Objen hedefine ulaştığında animasyonunun duracağı anlamına gelir. Nesnenin her zaman dönmesi veya bir defa hareket edip durması gerekmiyorsa animasyon modunu Pinpon moduna ayarla. Pinpon kullanarak metronomdaki çubuk veya yükselip alçalan köprü gibi ileri geri salınan objeler yapabilirsin. 
     # Oynatılacak varsayılan animasyon modunu ayarla.
 # OneShot animasyon modu, animasyonu bir defa oynatır.
 var AnimationMode:animation_mode := animation_mode.OneShot

 # RootProp özelliğinin dönmeyi bitirdiğinde sıfırlanmaması ve durmaması gerekiyorsa,
 # animasyon modunu PingPong olarak ayarla.
 if:
     not ShouldRotateForever? and not MoveOnceAndStop?
 then:
     set AnimationMode = animation_mode.PingPong

    ShouldReset false ve ShouldRotateForever true olarak ayarlanırsa nesnen, Move() döngüsüne devam ederken her animasyondan sonra konumunu korumalıdır.

  7. StartingTransform öğesindeyken RotateBy() çağırıp TargetRotationı geçirerek RotateByMoveRotation adında yeni bir değişkene doğru dönmek için kök nesnenin dönüşünü al. Ardından MoveToEase() çağrısı yap. Tamamlanmış Move() fonksiyonun şu şekilde görünmelidir.

     # RootProp’u TargetRotation uygulayarak veya ayarlanmışsa MovePosition öğesine doğru döndür.
 Move<override>()<suspends>:void=

     # MoveTarget ayarlanmışsa TargetRotation öğesini MoveTarget dönüşüne ayarla.
     if:
         RotationToMatch := MatchRotationTarget?.GetTransform().Rotation
     then:
         set TargetRotation = RotationToMatch
     else:
         set TargetRotation = AdditionalRotation
            
     # Oynatılacak varsayılan animasyon modunu ayarla.
     # OneShot animasyon modu, animasyonu bir defa oynatır.
     var AnimationMode:animation_mode := animation_mode.OneShot
     # RootProp özelliğinin dönmeyi bitirdiğinde sıfırlanmaması ve durmaması gerekiyorsa,
     # animasyon modunu PingPong olarak ayarla.
     if:
         not ShouldRotateForever? and not MoveOnceAndStop?
     then:
         set AnimationMode = animation_mode.PingPong
     # StartTransform özelliğini
     # AdditionalRotation ile döndürerek dönüş yönünü al. Ardından dönüşü başlat.
     RotateByTargetRotation := StartingTransform.Rotation.RotateBy(TargetRotation)
     RootProp.MoveToEase(RotateByTargetRotation, MoveDuration, MoveEaseType, AnimationMode)

  8. prop_animator cihaz sınıfında, RotatingProps adında düzenlenebilir yeni bir rotating_prop dizisi ekle. Dönen tüm nesneler arasında dolaşan ve üzerine gelindiğinde Setup() özelliğini çağıran OnBegin() öğesine başka bir for ifadesi ekle. Güncellenen prop_animator sınıfın şu şekilde görünmelidir:

     using { /Fortnite.com/Devices }
 using { /Verse.org/Simulation }
 using { /UnrealEngine.com/Temporary/Diagnostics }

 TranslatingPropsTip<localizes>:message = "Animasyonu kullanarak yer değiştiren (hareket eden) nesneler."
 RotatingPropsTip<localizes>:message = "Animasyonu kullanarak dönen nesneler."

 # Her bir nesnenin Setup() metodunu çağırarak, animasyonda hareket eden nesneleri koordine eder.
 prop_animator := class(creative_device):

     # Animasyon kullanılarak hareket ettirilen nesnelerin dizisi.
     @editable
     TranslatingProps:[]translating_prop = array{}

     @editable
     RotatingProps:[]rotating_prop = array{}

     # Cihaz, çalışmakta olan bir oyunda başlatıldığında çalışır
     OnBegin<override>()<suspends>:void=

         # Her bir nesne için Setup() özelliğini çağırarak animasyona başla.
         for:
             Prop:TranslatingProps
         do:
             Prop.Setup()
         for:
             Prop:RotatingProps
         do:
             Prop.Setup()
  9. Kodunu kaydet ve onu derle.

Nesneleri Cihazlara Bağlama

Editöre geri dönerek başka bir boşluk oluşturmak için hareketli nesneler bölümünden sonra nesnelerin bazılarını sil. Bölümüne FG01 Döner Platform tabanı ve FG01 SpinningBar İkili S ekle. Tabanı RotatingBase ve çubuğu Döner Çubuk olarak adlandır. Çubuğu tabanın üzerine konumlandır ve her iki nesneyi de boşluğun üzerine yerleştir.

Dönen iki nesnenin kurulumu. Döner çubuk ve dönen taban aynı yönde farklı hızlarda döner.

Anahat Düzenleyicideyken nesne animatörünü seç ve dönen nesnelerin her biri için RotatingProps işlevine bir dizi elementi ekle. Her bir nesneye aşağıdaki değerleri ata:

Seçenek Değer Açıklama
Ek Dönüş Z, 90.0 Bu nesne her seferinde Z ekseni etrafında 90 derecelik bir dönüş yapar.
RootProp Animasyonunu yaptığın nesneye ata Bu, animasyonunu yaptığın nesnedir.
Hareket Süresi 2.0, 3.0 Farklı hızlarda dönmeleri için nesnelerden birine daha kısa bir süre ata.
Hareket Yavaşlatma Türü Doğrusal Bu, nesnelerinin animasyonunu tutarlı bir hızda yapar.

Değişiklikleri uygula ardından nesnelerini kontrol et! Farklı dönüşler elde etmek için farklı değerler kullanmayı dene, farklı türde engeller oluşturmak için ise farklı boyutların her birinde dönüşü dene.

Gelecek Ders

Sonraki bölümde, her ikisini de yapabilen nesneler oluşturmak için hareket ile dönüşü birleştireceksin!

Tam Kod

Bu bölümde oluşturulan kodun tamamı şöyledir:

rotating_prop.verse

using { /Fortnite.com/Devices }
using { /Fortnite.com/Devices/CreativeAnimation }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/SpatialMath }

AdditionalRotationTip<localizes>:message = "RootProp’a uygulanacak dönüş."
ShouldRotateForeverTip<localizes>:message = "RootProp’un her zaman dönmesi gerekip gerekmediğini gösterir."
MatchRotationTargetTip<localizes>:message = "Dönüşü RootProp dönüşüyle aynı olması gereken isteğe bağlı nesne. Bir Ek Dönüş ayarlamak istemezsen bunu kullan."

# Ek bir dönüş yaparak dönen veya kreatif nesnesi dönüşü ile eşleşecek 
# şekilde dönen bir nesne.
rotating_prop<public> := class<concrete>(movable_prop):
    
    # RootProp’a uygulanacak ek dönüş.
    @editable {ToolTip := AdditionalRotationTip}
    AdditionalRotation:rotation = rotation{}

    # RootProp’un sonsuza dek dönüp dönmeyeceğini gösterir.
    @editable {ToolTip := ShouldRotateForeverTip}
    ShouldRotateForever:logic = true

    # Dönüşü RootProp dönüşüyle eşleşmesi gereken isteğe bağlı nesne. Bunu kullanmak için
    # ek bir dönüş ayarlamak istemiyor olman gerekir.
    @editable {ToolTip := MatchRotationTargetTip}
    MatchRotationTarget:?creative_prop = false

    # Nesnenin halihazırda dönme işlemini gerçekleştirdiği dönüş yönüdür.
    var TargetRotation:rotation = rotation{}
    
    # RootProp’u TargetRotation uygulayarak veya ayarlanmışsa MoveTarget hedefine doğru döndür.
    Move<override>()<suspends>:void=

        # Ayarlanmışsa, TargetRotation öğesini RotationToMatch olarak ayarla. Aksi takdirde
        # AdditionalRotation olarak ayarla.
        if:
            RotationToMatch := MatchRotationTarget?.GetTransform().Rotation
        then:
            set TargetRotation = RotationToMatch
        else:
            set TargetRotation = AdditionalRotation
            
        # Oynatılacak varsayılan animasyon modunu ayarla. 
        # OneShot animasyon modu, animasyonu bir defa oynatır. 
        var AnimationMode:animation_mode := animation_mode.OneShot
        # RootProp özelliğinin dönmeyi bitirdiğinde sıfırlanmaması ve durmaması gerekiyorsa,
        # animasyon modunu PingPong olarak ayarla.
        if:
            not ShouldRotateForever? and not MoveOnceAndStop?
        then:
            set AnimationMode = animation_mode.PingPong
        # StartTransform’u 
        # AdditionalRotation ile döndürerek dönüş yönünü al. Ardından dönüşü başlat.
        RotateByTargetRotation := StartingTransform.Rotation.RotateBy(TargetRotation)
        RootProp.MoveToEase(RotateByTargetRotation, MoveDuration, MoveEaseType, AnimationMode)

prop_animator.verse

using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/Diagnostics }

TranslatingPropsTip<localizes>:message = "Animasyonu kullanarak yer değiştiren (hareket eden) nesneler."
RotatingPropsTip<localizes>:message = "Animasyonu kullanarak dönen nesneler."

# Her bir nesnenin Setup() metodunu çağırarak, animasyonda hareket eden nesneleri koordine eder.
prop_animator := class(creative_device):

    # Animasyon kullanılarak hareket ettirilen nesnelerin dizisi.
    @editable
    TranslatingProps:[]translating_prop = array{}

    @editable
    RotatingProps:[]rotating_prop = array{}

    # Cihaz, çalışmakta olan bir oyunda başlatıldığında çalışır
    OnBegin<override>()<suspends>:void=


        # Her bir nesne için Setup() özelliğini çağırarak animasyona başla.
        for:
            Prop:TranslatingProps
        do:
            Prop.Setup()
        for:
            Prop:RotatingProps
        do:
            Prop.Setup()

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page