4. Assegnazione delle armi ai giocatori durante la generazione

Ora che hai distribuito in modo bilanciato i giocatori nei team, puoi procedi assegnando loro le armi corrette in base al team a cui sono stati assegnati. Segui i passaggi seguenti per imparare come assegnare ai giocatori le armi giuste al momento della loro generazione.

Assegnare le armi in base al team

1. Nella definizione della classe triad_infiltration_game, aggiungi una nuova funzione denominata GrantTeamWeapon(). Questa funzione consente di assegnare un'arma a un giocatore in base al suo team di appartenenza.

    GrantTeamWeapon(InPlayer:player):void=
   Copy full snippet

   GrantTeamWeapon(InPlayer:player):void=
2. In GrantTeamWeapon(), ottieni il team del giocatore indicato. Poi, in un loop for, scorri l'array Teams, ottenendo l'indice di quel team e memorizzandolo in una variabile TeamIndex. Controlla se il team del giocatore indicato corrisponde a questo team come condizione di filtro nel ciclo for.

    GrantTeamWeapon(InPlayer:player):void=
        if(CurrentTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]):
            for(TeamIndex -> PlayerTeam:Teams, PlayerTeam = CurrentTeam):
   Copy full snippet

   GrantTeamWeapon(InPlayer:player):void= if(CurrentTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]): for(TeamIndex -> PlayerTeam:Teams, PlayerTeam = CurrentTeam):
3. Poiché la tua condizione di filtro assicurerà che il codice all'interno del loop for venga eseguito con il team corretto, recupera l'assegnatore oggetti appropriato per quel team indicizzandolo in WeaponGranters utilizzando TeamIndex di quel team. Infine, chiama GrantItem() utilizzando il giocatore indicato. Il codice GrantTeamWeapon() dovrebbe essere simile al seguente:

    # Assegna un'arma ai giocatori in base all'indice del loro team nell'array Team
    # indicizzando l'array WeaponGranters.
    GrantTeamWeapon(InPlayer:player):void=
        if(CurrentTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]):
            for(TeamIndex -> PlayerTeam:Teams, PlayerTeam = CurrentTeam):
                if(WeaponGranter := WeaponGranters[TeamIndex]):
                    WeaponGranter.GrantItem(InPlayer)
                    Logger.Print("Arma assegnata a un giocatore del team {TeamIndex + 1}")
   Copy full snippet

   # Assegna un'arma ai giocatori in base all'indice del loro team nell'array Team # indicizzando l'array WeaponGranters. GrantTeamWeapon(InPlayer:player):void= if(CurrentTeam := GetPlayspace().GetTeamCollection().GetTeam[InPlayer]): for(TeamIndex -> PlayerTeam:Teams, PlayerTeam = CurrentTeam): if(WeaponGranter := WeaponGranters[TeamIndex]): WeaponGranter.GrantItem(InPlayer) Logger.Print("Arma assegnata a un giocatore del team {TeamIndex + 1}")

   Assicurati che l'ordine dei tuoi team nell'array Teams corrisponda all'ordine dei tuoi assegnatori oggetti in WeaponGranters. Se gli Infiltrati appartengono al Team 1, di conseguenza il primo assegnatore in WeaponGranters sarà previsto per gli Infiltrati. Controlla nell'editor che i valori siano corretti.

Assegnare le armi durante la generazione dei giocatori

1. Nella definizione della classe triad_infiltration_game, aggiungi una nuova funzione OnPlayerSpawn(). Questa funzione prende un agent e lo utilizza per chiamare GrantTeamWeapon() al fine di assegnare l'arma appropriata al giocatore.

    OnPlayerSpawn(SpawnedAgent:agent):void=
   Copy full snippet

   OnPlayerSpawn(SpawnedAgent:agent):void=
2. In OnPlayerSpawn(), lancia SpawnedAgent in un player. Quindi chiama GrantTeamWeapon() passando il giocatore. La tua funzione OnPlayerSpawn() dovrebbe essere simile alla seguente:

    # Viene eseguito quando avviene la generazione di qualsiasi giocatore su una piattaforma di generazione.
    # Chiama GrantTeamWeapon utilizzando lo SpawnedAgent fornito.
    OnPlayerSpawn(SpawnedAgent:agent):void=
        if(SpawnedPlayer := player[SpawnedAgent]):
            Logger.Print("Tentativo di assegnare un'arma al giocatore generato")
            GrantTeamWeapon(SpawnedPlayer)
   Copy full snippet

   # Viene eseguito quando avviene la generazione di qualsiasi giocatore su una piattaforma di generazione. # Chiama GrantTeamWeapon utilizzando lo SpawnedAgent fornito. OnPlayerSpawn(SpawnedAgent:agent):void= if(SpawnedPlayer := player[SpawnedAgent]): Logger.Print("Tentativo di assegnare un'arma al giocatore generato") GrantTeamWeapon(SpawnedPlayer)
3. In OnBegin(), prima di chiamare BalanceTeams(), sottoscrivi l'evento SpawnedEvent di ogni giocatore, utilizzando un loop for alla funzione OnPlayerSpawn() appena definita.

    OnBegin<override>()<suspends>:void =
        # Ottieni tutti i team
        set Teams = GetPlayspace().GetTeamCollection().GetTeams()
        # Salva i team per farvi riferimento in seguito
        set InfiltratorsOpt = option{Teams[0]}
        set AttackersOpt = option{Teams[1]}
        set DefendersOpt = option{Teams[2]}
        if:
            Infiltrators := InfiltratorsOpt?
            Attackers := AttackersOpt?
            Defenders :=  DefendersOpt?
            Logger.Print("Sono stati trovati tutti e tre i team")
            set TeamsAndTotals[Infiltrators] = MaximumInfiltrators
            set TeamsAndTotals[Attackers] = MaximumAttackers
            set TeamsAndTotals[Defenders] = MaximumDefenders
            Logger.Print("Configura tutti e tre i team in TeamsAndTotals")
        then:
            #Sottoscrive l'evento PlayerAddedEvent per consentire il ribilanciamento del team quando un nuovo giocatore si unisce al gioco
            for(PlayerSpawner:PlayersSpawners):
                PlayerSpawner.SpawnedEvent.Subscribe(OnPlayerSpawn)
            BalanceTeams()
            TeleportPlayersToStartLocations()
        else:
            Logger.Print("Impossibile trovare tutti i team: assicurati di assegnare i team corretti nelle impostazioni della tua isola.")
   Copy full snippet

   OnBegin<override>()<suspends>:void = # Ottieni tutti i team set Teams = GetPlayspace().GetTeamCollection().GetTeams() # Salva i team per farvi riferimento in seguito set InfiltratorsOpt = option{Teams[0]} set AttackersOpt = option{Teams[1]} set DefendersOpt = option{Teams[2]} if: Infiltrators := InfiltratorsOpt? Attackers := AttackersOpt? Defenders := DefendersOpt? Logger.Print("Sono stati trovati tutti e tre i team") set TeamsAndTotals[Infiltrators] = MaximumInfiltrators set TeamsAndTotals[Attackers] = MaximumAttackers set TeamsAndTotals[Defenders] = MaximumDefenders Logger.Print("Configura tutti e tre i team in TeamsAndTotals") then: #Sottoscrive l'evento PlayerAddedEvent per consentire il ribilanciamento del team quando un nuovo giocatore si unisce al gioco for(PlayerSpawner:PlayersSpawners): PlayerSpawner.SpawnedEvent.Subscribe(OnPlayerSpawn) BalanceTeams() TeleportPlayersToStartLocations() else: Logger.Print("Impossibile trovare tutti i team: assicurati di assegnare i team corretti nelle impostazioni della tua isola.")

4. Salva lo script, compilalo e fai clic su Avvia sessione nella barra degli strumenti UEFN per eseguire il playtest del livello. Durante il playtest del livello, ogni giocatore deve essere assegnato al team con la differenza maggiore ed essere generato con un'arma appropriata per il suo team. Verifica questo comportamento utilizzando il registro.

   

Passaggio successivo

Nel passaggio successivo di questo tutorial, imparerai come rendere gli Infiltrati invisibili quando vengono generati all'inizio di una partita.