Plantilla de eliminación de Verse

En Eliminación de Verse, los jugadores lucharán con un equipo que cambia con cada eliminación. Estas mecánicas se consiguen vinculando dispositivos como el dispositivo Repartidor de objetos al dispositivo de Verse.

Esta plantilla avanzada de Verse te mostrará el uso de estas API de Verse:

• Un contenedor de tipo mapa

• Matrices

• Suscripción de Fort_character a EliminateEvent

Resumen

1. Crea un nuevo proyecto y modifica la configuración de la isla para definir el juego.

2. Configura los dispositivos.

3. Añade la secuencia de comandos de Verse.

4. Configura el dispositivo de Verse.

Cómo crear un nuevo proyecto y configurar el juego

1. Abre UEFN y crea un nuevo proyecto vacío.

2. Selecciona el dispositivo Configuración de la isla en el esquematizador y localiza Opciones de usuario - Reglas del juego.

1. Modifica las opciones de usuario como se muestra a continuación.

Cómo configurar los dispositivos

Este tutorial utiliza los siguientes dispositivos:

• Cualquier número de repartidores de objetos

• Un dispositivo Fin de partida

• Cualquier número de plataformas de aparición de jugador

Dispositivo Repartidor de objetos

Utiliza un dispositivo Repartidor de objetos para conceder armas a los jugadores. Después de conectar el repartidor de objetos al dispositivo de Verse mediante el vínculo directo de evento, la secuencia de comandos de Verse puede aleatorizar el orden de las armas y otorgarlas con cada eliminación.

Puedes utilizar cualquier número de repartidores de objetos. Siempre que los enlaces en la matriz de dispositivos de Verse, el juego se escalará en consecuencia.

Desde el almacén de contenido, ve a Fortnite > Dispositivos y arrastra los repartidores de objetos a tu mapa.

Para configurar este dispositivo, establece las Opciones de usuario como se indica a continuación:

Dispositivo Fin de partida

Utiliza un dispositivo Fin de partida para terminar la ronda cuando se cumplan las condiciones. Cuando las eliminaciones alcancen un determinado umbral, la secuencia de comandos de Verse activará este dispositivo para finalizar la ronda.

Utiliza la configuración predeterminada para este dispositivo.

Plataforma de aparición de jugador

Puedes utilizar plataformas de aparición de jugador para generar jugadores en tu mapa. Distribuye uniformemente las plataformas de aparición por el mapa para que los jugadores no se agrupen.

Utiliza la configuración predeterminada para este dispositivo.

Cómo añadir secuencias de comandos de Verse

Añade las siguientes secuencias de comandos de Verse. Empieza haciendo referencia a los dispositivos con la función @editable.

Puedes copiar el código en el orden en que está escrito. Se añaden comentarios dentro de la secuencia de comandos para mayor claridad.

using { /Fortnite.com/Devices }
using { /Fortnite.com/Characters }
using { /Fortnite.com/Game }
using { /Verse.org/Simulation }
using { /Verse.org/Simulation/Tags }
using { /Verse.org/Random }
using { /UnrealEngine.com/Temporary/Diagnostics }

elimination_game_device := class(creative_device):

    @editable
    EndGameDevice : end_game_device = end_game_device{}

    # Matriz de repartidores de objetos utilizados para suministrar las armas
    @editable
    var WeaponItemGranters : []item_granter_device = array{}
    
    # Esto se establece más tarde, será igual al número de item_granters de armas en la isla
    var NumberOfEliminationsToWin : int = 0
    # Contenedor de tipo mapa para seguir el progreso de los jugadores. Así se determina qué arma se concede al jugador.
    var AgentMap : [agent]int = map{}

Copy full snippet

using { /Fortnite.com/Devices } using { /Fortnite.com/Characters } using { /Fortnite.com/Game } using { /Verse.org/Simulation } using { /Verse.org/Simulation/Tags } using { /Verse.org/Random } using { /UnrealEngine.com/Temporary/Diagnostics } elimination_game_device := class(creative_device): @editable EndGameDevice : end_game_device = end_game_device{} # Matriz de repartidores de objetos utilizados para suministrar las armas @editable var WeaponItemGranters : []item_granter_device = array{} # Esto se establece más tarde, será igual al número de item_granters de armas en la isla var NumberOfEliminationsToWin : int = 0 # Contenedor de tipo mapa para seguir el progreso de los jugadores. Así se determina qué arma se concede al jugador. var AgentMap : [agent]int = map{}

El código anterior muestra las definiciones de las variables.

    OnBegin<override>()<suspends>:void=
        # Puedes utilizar esta variable para escalar el número de eliminaciones necesarias en función de cuántos repartidores de objetos haya en la experiencia
        set NumberOfEliminationsToWin = WeaponItemGranters.Length
        Print("Número de repartidores de objetos de armas: {WeaponItemGranters.Length}")
        
        # Aleatoriza el orden de concesión de las armas
        set WeaponItemGranters = Shuffle(WeaponItemGranters)

        # Consigue que todos los jugadores participen en la experiencia
        AllPlayers := GetPlayspace().GetPlayers()
        for (EliminationGamePlayer : AllPlayers):
            if (FortCharacter := EliminationGamePlayer.GetFortCharacter[]):
                FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) # Suscríbete al evento eliminado
            
            # Añade jugadores a un mapa para seguir el progreso
            if (set AgentMap[EliminationGamePlayer] = 1) {} 
            
            # Concede la primera arma a cada jugador
            if (FirstItemGranter:item_granter_device = WeaponItemGranters[0]):
                FirstItemGranter.GrantItem(EliminationGamePlayer) 
Copy full snippet

OnBegin<override>()<suspends>:void= # Puedes utilizar esta variable para escalar el número de eliminaciones necesarias en función de cuántos repartidores de objetos haya en la experiencia set NumberOfEliminationsToWin = WeaponItemGranters.Length Print("Número de repartidores de objetos de armas: {WeaponItemGranters.Length}") # Aleatoriza el orden de concesión de las armas set WeaponItemGranters = Shuffle(WeaponItemGranters) # Consigue que todos los jugadores participen en la experiencia AllPlayers := GetPlayspace().GetPlayers() for (EliminationGamePlayer : AllPlayers): if (FortCharacter := EliminationGamePlayer.GetFortCharacter[]): FortCharacter.EliminatedEvent().Subscribe(OnPlayerEliminated) # Suscríbete al evento eliminado # Añade jugadores a un mapa para seguir el progreso if (set AgentMap[EliminationGamePlayer] = 1) {} # Concede la primera arma a cada jugador if (FirstItemGranter:item_granter_device = WeaponItemGranters[0]): FirstItemGranter.GrantItem(EliminationGamePlayer)

El código anterior muestra la lógica que establece la regla de juego de cuántas eliminaciones se necesitan para ganar. Se aleatoriza el orden de la matriz del repartidor de objetos.

Los jugadores se añaden a un mapa para controlar tanto su progreso como el siguiente objeto que se les debe conceder.

    # Evento que gestiona la eliminación de un jugador
    OnPlayerEliminated(Result:elimination_result):void=
        Print("Jugador eliminado")
        EliminatingCharacter := Result.EliminatingCharacter
        if (FortCharacter := EliminatingCharacter?):
            if (EliminatingAgent := FortCharacter.GetAgent[]):
                GrantNextWeapon(EliminatingAgent)
Copy full snippet

# Evento que gestiona la eliminación de un jugador OnPlayerEliminated(Result:elimination_result):void= Print("Jugador eliminado") EliminatingCharacter := Result.EliminatingCharacter if (FortCharacter := EliminatingCharacter?): if (EliminatingAgent := FortCharacter.GetAgent[]): GrantNextWeapon(EliminatingAgent)

El código anterior es el evento que ocurre cuando un jugador es eliminado. Al jugador eliminado se le concede la siguiente arma.

    # Comprueba si hay un ganador de la partida; si no es así, concede la siguiente arma
    GrantNextWeapon(Agent:agent):void=
        if (var CurrentItemNumber:int = AgentMap[Agent]):
            if (IsVictoryConditionMet(CurrentItemNumber) = true):
                EndGame(Agent) # Alguien ha ganado el juego
            else: # El juego aún no ha terminado
                set CurrentItemNumber = CurrentItemNumber + 1
                if (ItemGranter := WeaponItemGranters[CurrentItemNumber - 1]):
                    ItemGranter.GrantItem(Agent)
                
                if (set AgentMap[Agent] = CurrentItemNumber) {}
Copy full snippet

# Comprueba si hay un ganador de la partida; si no es así, concede la siguiente arma GrantNextWeapon(Agent:agent):void= if (var CurrentItemNumber:int = AgentMap[Agent]): if (IsVictoryConditionMet(CurrentItemNumber) = true): EndGame(Agent) # Alguien ha ganado el juego else: # El juego aún no ha terminado set CurrentItemNumber = CurrentItemNumber + 1 if (ItemGranter := WeaponItemGranters[CurrentItemNumber - 1]): ItemGranter.GrantItem(Agent) if (set AgentMap[Agent] = CurrentItemNumber) {}

El código anterior es la lógica para determinar tanto qué arma se le concede al jugador eliminado como si está en la última arma para terminar la partida.

    # Comprueba si se cumple la condición de victoria y devuelve el resultado
    IsVictoryConditionMet(EliminationNumber:int)<transacts>:logic=
        if:
            EliminationNumber = NumberOfEliminationsToWin
        then:
            return true
        else:
            return false
Copy full snippet

# Comprueba si se cumple la condición de victoria y devuelve el resultado IsVictoryConditionMet(EliminationNumber:int)<transacts>:logic= if: EliminationNumber = NumberOfEliminationsToWin then: return true else: return false

El código anterior es la lógica para comprobar si se ha cumplido la condición de victoria.

    EndGame(Agent:agent):void=
        EndGameDevice.Activate(Agent)
Copy full snippet

EndGame(Agent:agent):void= EndGameDevice.Activate(Agent)

El código anterior es la lógica que muestra el dispositivo Fin de partida llamando al jugador ganador.

Cómo configurar el dispositivo de Verse

El dispositivo de Verse controla el fin de la partida y la concesión de armas al ser eliminado a través de una serie de repartidores de objetos conectados mediante el vínculo directo de evento.

Compila tu secuencia de comandos de Verse y busca tu dispositivo en el almacén de contenido. Arrastra el dispositivo de Verse a una zona no visible de tu mapa para personalizar la configuración.

Utiliza este dispositivo para establecer el vínculo directo de evento en los dispositivos necesarios con el fin de que puedan ser referenciados por la secuencia de comandos de Verse.

En el panel Detalles del dispositivo, configura los ajustes para que coincidan con cada dispositivo referenciado, como en la foto de arriba.

Para configurar este dispositivo, establece las Opciones de usuario como se indica a continuación:

Selecciona Abrir sesión para probar tu nivel finalizado.