1. Epic GamesDeveloper
  3. Verschwindende Plattform bei Berührung

Verschwindende Plattform bei Berührung

Erstelle mit Verse eine Plattform, die verschwindet, wenn der Spieler sie berührt, und nach einer zufälligen Anzahl von Sekunden wieder auftaucht.

Verschwindende Plattform bei Berührung

Plattformen, die verschwinden, wenn du auf ihnen landest, sind ein fester Bestandteil von Jump'n'Run-Spielen wie Hindernisparcours. Sie verlangen von den Spielern, dass sie schnell handeln und planen, wohin sie gehen, damit sie nicht runterfallen.

In diesem Tutorial erfährst du, wie du mit Verse in Unreal Editor für Fortnite (UEFN) eine Plattform baust, die verschwindet, wenn der Spieler sie berührt, und nach einer zufälligen Anzahl von Sekunden wieder auftaucht. Dieses Beispiel zeigt, wie man ein Gebiet erstellt, in dem der Spieler von Plattform zu Plattform springen muss, um nicht zu fallen. Das vollständige Script ist am Ende dieses Leitfadens als Referenz enthalten.

Eine Plattform, die verschwindet, wenn der Spieler sie berührt, und nach einer zufälligen Anzahl von Sekunden wieder auftaucht, wenn sie berührt wird, mit Verse

Verse Sprachfunktion verwendet

Verwendete APIs in Verse

  • Sleep(): Die API Sleep() wird verwendet, um die Verzögerungen zwischen dem Verschwinden der Plattform und dem Wiederauftauchen nach einer zufälligen Zeit einzufügen.

  • GetRandomFloat(): Die API GetRandomFloat() wird verwendet, um eine zufällige Zeitspanne zu berechnen, bevor die Plattform wieder auftaucht.

  • Editable Properties: UEFN verfügt über vier Eigenschaften - drei Floats, um die Verzögerungen für das Verschwinden und Wiederauftauchen der Plattform zu steuern, und die Plattformreferenz selbst.

  • [Geräte-Events](coding-device-interactions-in-verse: Du wirst das TriggeredEvent des Auslöser-Geräts nutzen, um zu erfahren, wenn ein Spieler auf der Plattform landet.

Einrichten des Levels

Dieses Tutorial verwendet Verse-Starter-Vorlage als Ausgangspunkt. Als Erstes initialisierst du ein neues Projekt aus dem Funktionsbeispiel Verse-Gerät.

Startinsel-Vorlage initialisieren

Dieses Beispiel verwendet die folgenden Props und Geräte.

  • 1 x Spieler-Spawnfläche-Gerät: Dieses Gerät legt fest, wo der Spieler zu Beginn des Spiels spawnen wird.

  • 4 x Kreativobjekt: Kreativobjekte haben mehrere Verhaltensweisen, die du mit Verse aufrufen kannst, wie z. B. Hide() und Show(), um die Sichtbarkeit und Kollision der Plattform umzuschalten. Dieses Tutorial verwendet die Fliegende Schwebeplattform A** als player-interactable-Plattform, du kannst diese jedoch gerne deinen Anforderungen nach ändern.

  • 4 x Auslöser-Gerät: Du wirst die Trigger nutzen, um zu erfahren, wenn ein Spieler auf der Plattform landet.

Befolge diese Schritte, um dein Level einzurichten:

  1. Füge deiner Szene eine Fliegende Schwebeplattform A hinzu. Platziere sie über der Plattform. Das ist der Ort, an dem der Spieler zu Beginn des Spiels spawnen wird. Benenne im Outliner die Plattform RecyclePlatform.

    Wähle recycle_platform im Outliner

  2. Füge deiner Szene ein Auslöser-Gerät hinzu und lege es als Child deiner RecyclePlatform fest. Platziere es oben auf der Plattform und ändere seine Größe, dass es auf die gesamte Plattform passt. Setze im Outliner die Option Sichtbar im Spiel auf False und Anzahl der Auslösungen auf 1.

    Platziere den Trigger auf der Plattform

  3. Platziere das Spieler-Spawnfläche-Gerät auf der Plattform. Das ist der Ort, an dem der Spieler zu Beginn des Spiels spawnen wird. Deaktiviere in Outliner die Option Im Spiel sichtbar, damit der Spieler nach dem Spawnen nicht auf dem Spawn-Pad stehen kann. Dein fertiges Setup sollte wie folgt aussehen:

    Platziere die Spieler-Spawnfläche auf der Plattform

Erstellen des Geräts

In diesem Beispiel wird ein Verse-autorisiertes Gerät verwendet, um das Verhalten dafür zu definieren, dass die Plattform verschwindet, wenn der Spieler darauf landet, und eine zufällige Anzahl von Sekunden später wieder erscheint. Befolge diese Schritte, um dieses Gerät mit Verse zu erstellen.

  1. Erstelle ein neues Verse-Gerät mit dem Namen disappear_on_touch_platform mit dem Verse-Explorer. Wie du ein neues Gerät in Verse erstellen kannst, erfährst du unter Erstelle dein eigenes Gerät mit Verse.

    Erstelle ein neues Verse-Gerät mit dem Namen disappear_on_touch_platform

  2. Ziehe das Gerät disappear_on_touch_platform aus dem Inhaltsbrowser in das Level.

Bearbeiten der Geräteeigenschaften in UEFN

In diesem Abschnitt wird gezeigt, wie du vier Geräteeigenschaften für UEFN freigeben kannst, damit du sie im Editor anpassen kannst:

  • Ein Geräteverweis auf das Kreativobjekt, das du im Level platziert hast.

  • Eine float-Konstante mit dem Namen DisappearDelay, um zu speichern, wie lange gewartet werden soll, nachdem der Spieler die Plattform berührt hat, bevor sie versteckt wird.

  • Zwei Float-Konstanten mit den Namen DelayMin und DelayMax speichern die minimale und maximale Zeit, die gewartet werden muss, bevor die Plattform wieder erscheint. Diese beiden Werte legen den erlaubten Bereich für die Ermittlung einer Zufallszahl fest.

Befolge diese Schritte, um diese Eigenschaften des Geräts disappear_on_touch_platform, das du im vorherigen Abschnitt erstellt hast, freizugeben.

  1. Öffne den Verse-Explorer und doppelklicke auf disappear_on_touch_platform.verse, um das Script in Visual Studio Code zu öffnen.

  2. Füge in der Klassendefinition von disappear_on_touch_platform die folgenden Felder hinzu:

    • Ein bearbeitbarer float mit dem Namen DisappearDelay. So lange wird gewartet, nachdem der Spieler die Plattform berührt hat, bevor sie versteckt wird. Initialisiere diesen Wert auf 1.0 oder eine Sekunde.

        # Wie lange wird gewartet, nachdem der Spieler die Plattform berührt hat, bevor sie versteckt wird.
  @editable
  DisappearDelay:float = 1.0

    • Ein bearbeitbarer float mit dem Namen DelayMin. Dies ist die Mindestzeit, die gewartet werden muss, bevor die Plattform wieder auftaucht. Initialisiere das auf 3.0 oder drei Sekunden.

        # Die Mindestzeit, die gewartet werden muss, bevor die Plattform wieder auftaucht.
  @editable
  DelayMin:float = 3.0

    • Ein bearbeitbarer float mit dem Namen DelayMax. Dies ist die maximale Zeit, die gewartet werden muss, bevor die Plattform wieder auftaucht. Initialisiere das auf 4.0 oder vier Sekunden.

        # Die maximale Zeit, die gewartet werden muss, bevor die Plattform wieder auftaucht.
  @editable
  DelayMax:float = 4.0

    • Ein bearbeitbares creative_prop mit dem Namen DisappearingPlatform. Das ist die Level-Plattform, die in regelmäßigen Abständen verschwindet und wieder erscheint. Da dein Code noch keinen Verweis auf dieses Objekt im Level hat, instanziiere dies mit einem leeren Archetyp creative_prop{}. Diese Referenz weist du später deiner schwebenden Plattform zu.

        # Bezug auf die Plattform im Level.
  @editable
  DisappearingPlatform:creative_prop = creative_prop{}

    • Ein bearbeitbares trigger_device mit dem Name nPlatformTrigger. Du wirst das TriggeredEvent-Event von diesem Gerät brauchen, um zu wissen, wann ein Spieler auf der Plattform landet.

        # Die Zone die ein Spieler betritt, wenn er auf der Plattform landet.
  @editable
  PlatformTrigger:trigger_device = trigger_device{}

  3. Die Felder deiner Klasse Disappear_on_touch_platform sollten wie folgt aussehen:

     # Ein mit Verse erstelltes Kreativmodus-Gerät, das in einem Level platziert werden kann
 disappear_on_touch_platform := class(creative_device):

     # Wie lange wird gewartet, nachdem der Spieler die Plattform berührt hat, bevor sie versteckt wird.
     @editable
     DisappearDelay:float = 1.0

     # Die Mindestzeit, die gewartet werden muss, bevor die Plattform wieder auftaucht.
     @editable
     DelayMin:float = 3.0

     # Die maximale Zeit, die gewartet werden muss, bevor die Plattform wieder auftaucht.
     @editable
     DelayMax:float = 4.0

     # Bezug auf die Plattform im Level.
     @editable
     DisappearingPlatform:creative_prop = creative_prop{}

     # Die Zone die ein Spieler betritt, wenn er auf der Plattform landet.
     @editable
     PlatformTrigger:trigger_device = trigger_device{}

    Es ist hilfreich, das Attribut @editable zu verwenden, um Werte wie ToggleDelay aus deinen Scripts dem Editor zugänglich zu machen. Auf diese Weise kannst du ihre Werte in UEFN anpassen, ohne den Verse-Code jedes Mal neu erstellen zu müssen. Somit kannst du schnell iterieren und Werte finden, die zu deinem Spielerlebnis passen.

  4. Speichere das Script in Visual Studio Code.

  5. Klicke in der UEFN-Symbolleiste auf Verse und dann auf Build Verse Code, um das Gerät disappear_on_touch_platform zu aktualisieren, das sich im Level befindet.

  6. Wähle im Outliner-Panel in UEFN das Gerät disappear_on_touch_platform aus, um sein Detail-Panel zu öffnen.

  7. Setze im Details-Panel unter Ausblenden bei Berührung die Plattform auf RecyclePlatform (das Kreativobjekt, das du dem Level hinzugefügt hast), indem du auf den Objektwähler klickst und das Gerät mit der Plattform im Viewport auswählst.

    Setze die Plattform auf dem Verse-Gerät auf recycle_platform

  8. Jetzt, wo du eine Prop-Referenz mit deinem Verse-Gerät verbunden hast, wählst du beide Geräte aus und duplizierst sie mehrmals im Level, um eine Reihe von Plattformen zu schaffen, zwischen denen der Spieler springen kann. Jedes neue Verse-Gerät, das du erstellst, sollte sich auf seine eigene Plattform beziehen.

    Dupliziere das Verse-Gerät und die Plattform, um dem Level mehr hinzuzufügen

Ausblenden und Einblenden der Plattform

Nachdem du nun das Level und die Geräte eingerichtet hast, kannst du die Funktion zum Ein- und Ausblenden der Plattform hinzufügen, wenn ein Spieler darauf landet. Befolge diese Schritte, um dieses Verhalten zur disappear_on_touch_platform-Klasse hinzuzufügen:

  1. Die creative_prop-Klasse hat zwei Methoden, um ihre Sichtbarkeit umzuschalten: Hide() und Show(). Zurück zum Visual Studio-Code, in OnBegin() mit dem Namen Hide() und dann auf Show() auf deiner DisappearingPlatform.

     # Wird ausgeführt, wenn das Gerät in einem laufenden Spiel gestartet wird
 OnBegin<override>()<suspends>:void=

     # Mache die Plattform unsichtbar.
     DisappearingPlatform.Hide()

     # Mache die Plattform sichtbar.
     DisappearingPlatform.Show()

    Wenn du diesen Code ausführst, wirst du nicht sehen, wie die Plattform verschwindet und wieder auftaucht, weil die Aufrufe Hide() und Show() unmittelbar nacheinander erfolgen.

  2. Damit die Plattform länger in einem sichtbaren / unsichtbaren Zustand bleibt, kannst du eine Verzögerung beim Aufruf von Hide() oder Show() mit Sleep() hinzufügen. Die Funktion Sleep() unterbricht die Ausführung einer Routine. Du gibst die Zeit (in Sekunden) an, während der die Ausführung unterbrochen werden soll, indem du der Funktion ein Float-Argument übergibst. Rufe Sleep() vor jedem Aufruf von Hide() und Show(), indem der DisappearDelay ausläuft, den du vorher definiert hast.

     # Wird ausgeführt, wenn das Gerät in einem laufenden Spiel gestartet wird
 OnBegin<override>()<suspends>:void=

     # Warte DisappearDelay Sekunden.
     Sleep(DisappearDelay)

     # Mache die Plattform unsichtbar.
     DisappearingPlatform.Hide()

     # Warte DisappearDelay Sekunden.
     Sleep(DisappearDelay)

     # Mache die Plattform sichtbar.
     DisappearingPlatform.Show()

    Nun, wenn du diesen Code ausführst, wird die Platform für eine Sekunde unsichtbar (die Zeit, die durchDisappearDelay definiert ist), bevor sie für den Rest des Spiels sichtbar wird.

    Die Funktion Sleep() kann nur in einem asynchronen Kontext aufgerufen werden. Die Methode OnBegin() ist bereits ein asynchroner Kontext, da sie über den Bezeichner suspends verfügt. Du musst daher nichts weiter tun. Um mehr über den Bezeichner suspends zu erfahren, siehe Bezeichner und Attribute.

  3. Wenn du die Zeit variierst, welche die Plattform braucht, um wieder aufzutauchen, kann das Spiel interessanter werden. Anstatt jedes Mal denselben Wert an Sleep() zu übergeben, kannst du mit der Funktion GetRandomFloat() eine zufällige Anzahl von Sekunden ermitteln und diesen Wert an Sleep() übergeben.

    • Füge am Anfang der Datei using { /Verse.org/Random } hinzu, um die Funktion GetRandomFloat() zu verwenden.

        using { /Fortnite.com/Devices }
  using { /Verse.org/Random }
  using { /Verse.org/Simulation }
  using { /UnrealEngine.com/Temporary/Diagnostics }

  # Unter https://dev.epicgames.com/documentation/de-de/uefn/create-your-own-device-in-verse erfährst du, wie du ein Verse-Gerät erstellst.

  # Ein mit Verse erstelltes Kreativmodus-Gerät, das in einem Level platziert werden kann

  disappear_on_touch_platform := class(creative_device):

    • Verwende die Funktion GetRandomFloat() als Argument für Sleep(), wenn du entscheidest, wie lange du warten willst, bevor du die Plattform wieder erscheinen lässt, und lege den erlaubten Bereich von Sekunden mit DelayMin und DelayMax fest.

        # Wird ausgeführt, wenn das Gerät in einem laufenden Spiel gestartet wird
  OnBegin<override>()<suspends>:void=

  # Warte DisappearDelay Sekunden.
  Sleep(DisappearDelay)

  # Mache die Plattform unsichtbar.
  DisappearingPlatform.Hide()

  # Warte zwischen DelayMin und DelayMax Sekunden.
  Sleep(GetRandomFloat(DelayMin, DelayMax))

  # Mache die Plattform sichtbar.
  DisappearingPlatform.Show()

    Jetzt wartet die Plattform 1.0 Sekunden, bevor sie verschwindet und erscheint dann 3.0 bis 4.0 Sekunden später wieder.

Erkennung der Landung des Spielers auf der Plattform

Um zu erkennen, wann der Spieler auf der Plattform landet, kannst du das TriggeredEvent [Ereignis](verse-glossary#ereignis) das die Klasse trigger_device zur Verfügung stellt, [abonnieren](verse-glossary#abonnieren). Der Trigger sendet das TriggeredEvent nur, wenn ein Spieler darüber läuft. Da du **Anzahl Auslösungen** auf eins gesetzt hast, musst du Reset() für den Trigger aufrufen, um seinen Status zurückzusetzen und ihm zu erlauben, das TriggeredEvent` erneut zu senden.

Befolge diese Schritte, um zu erkennen, wann der Spieler die Plattform berührt, und verwende den Code, den du im vorherigen Abschnitt geschrieben hast, um die Plattform als Reaktion darauf zu verstecken und wieder auftauchen zu lassen.

  1. Das TriggeredEvent benötigt eine Funktionssignatur mit einem optional player als Parameter und void als Rückgabetyp. Der Agent ist in dieser Funktion optional, da du Auslöser-Geräte auch über einen Code aktivieren kannst. Du musst also prüfen, ob ein Spieler derjenige war, der ihn aktiviert hat. Füge der Klasse disappear_on_touch_platform eine neue Methode namens OnPlayerTouch() hinzu.

     OnPlayerTouch(ActivatingPlayer:?agent):void=

  2. Versuche in OnPlayerTouch() mit einem if-Ausdruck den Spieler aus der Option ActivatingPlayer zu erhalten. Wenn dieser Aufruf erfolgreich ist, weiß du, dass ein Spieler den Trigger und nicht einen Code aktiviert hat.

     OnPlayerTouch(ActivatingPlayer:?agent):void=
     if:
         Spieler:= ActivatingPlayer?
     then:
         Print("Ein Spieler hat eine Plattform berührt!")

  3. Abonniere in OnBegin() den PlatformTrigger.TriggeredEvent mit OnPlayerTouchals Event-Handler. Immer wenn jetzt ein Spieler auf einer Plattform landet, wird das TriggeredEvent aktiviert und OnPlayerTouch()` ausgeführt.

     OnBegin<override>()<suspends>:void=

     # Abonnieren des TriggeredEvent des Plattformtriggers, um zu wissen,
     # wenn ein Spieler auf der Plattform landet.
     PlatformTrigger.TriggeredEvent.Subscribe(OnPlayerTouch)

  4. Wenn die Plattform ausgeblendet ist, sollten Spieler den Auslöser nicht aktivieren können, da sie direkt durch die Plattform hindurchgehen sollten. Um dies zu sichern, füge in OnBegin() Aufrufe zu PlatformTrigger.Disable() und Enable() nach Hide() bzw. Show() hinzu. Jetzt ist dein Trigger nicht interaktiv, während deine Plattform ausgeblendet ist.

     OnBegin<override>()<suspends>:void=

     # Abonnieren des TriggeredEvent des Plattformtriggers, um zu wissen,
     # wenn ein Spieler auf der Plattform landet.
     PlatformTrigger.TriggeredEvent.Subscribe(OnPlayerTouch)

     # Warte DisappearDelay Sekunden.
     Sleep(DisappearDelay)

     # Blende die Platform aus und deaktiviere den Trigger.
     DisappearingPlatform.Hide()
     PlatformTrigger.Disable()

     # Warte zwischen DelayMin und DelayMax Sekunden.
     Sleep(GetRandomFloat(DelayMin, DelayMax))

     # Zeig die Plattform und aktiviere den Trigger.
     DisappearingPlatform.Show()
     PlatformTrigger.Enable()

Obwohl du die Plattform ausblenden musst, wenn ein Spieler darauf landet, kannst du den Code zum Ausblenden und Anzeigen der Plattform nicht direkt zur Methode OnPlayerTouch() hinzufügen. Die Funktion Sleep() kann nur in einem asynchronen Kontext aufgerufen werden, und du kannst den Bezeichner suspends nicht zu OnPlayerTouch() hinzufügen, weil TriggeredEvent keine asynchronen Funktionen als Event-Handler erlaubt. Stattdessen kannst du spawn verwenden, um eine asynchrone Funktion aus OnPlayerTouch() aufzurufen. Folge diesen Schritten, um deine asynchrone Funktion hinzuzufügen.

  1. Füge der Klassendefinition disappear_on_touch_platformeine neue Methode namens RecyclePlatform() hinzu. Füge den Modifikator <suspends> hinzu, um die asynchrone Ausführung dieses Codes zu erlauben und verschiebe den Code zum Ausblenden und Anzeigen der Plattform und des Triggers von OnBegin in den Codeblock RecyclePlatform().

     # Blende die Platform aus und setze den PlatformTrigger zurück. Warte dann eine zufällige Zeitspanne und aktiviere die Anzeige der Plattform wieder.
 RecyclePlatform()<suspends> : void =

     # Warte DisappearDelay Sekunden.
     Sleep(DisappearDelay)

     # Blende die Platform aus und deaktiviere den Trigger.
     DisappearingPlatform.Hide()
     PlatformTrigger.Disable()

     # Warte zwischen DelayMin und DelayMax Sekunden.
     Sleep(GetRandomFloat(DelayMin, DelayMax))

     # Zeig die Plattform und aktiviere den Trigger.
     DisappearingPlatform.Show()
     PlatformTrigger.Enable()

  2. Rufe in OnPlayerTouch() spawn{} auf der RecyclePlatform(), um den Code asynchron auszuführen. Deine vollständige Funktion RecyclePlatform() sollte wie folgt aussehen:

     # Läuft, wenn ein Spieler auf der Plattform landet. Ruf RecyclePlatform() auf, um die Plattform zu verbergen.
 # und setzt den Triggerzustand zurück.
 OnPlayerTouch(ActivatingPlayer:?agent):void=
     if:
         Spieler:= ActivatingPlayer?
     then:
         Print("Ein Spieler hat eine Plattform berührt!")
         spawn{ RecyclePlatform() }

    Wenn du diesen Code ausführst, verschwindet die Plattform und taucht wieder auf, wenn der Spieler zum ersten Mal auf der Plattform landet.

    Asynchron deutet darauf hin, dass es einige Zeit dauern kann, bis ein Stück Code fertiggestellt ist. In diesem Fall dauert das Recyceln der Plattform zum Beispiel wegen der vielen Sleep()-Aufrufe ein paar Sekunden. Mit asynchronen Funktionen kannst du Operationen durchführen, ohne die Ausführung des Codes zu blockieren, der die asynchrone Funktion aufruft. Mehr über asynchrone Kontexte und den Ausdruck spawn erfährst du in Gleichzeitigkeit.

  3. Derzeit wird das TriggeredEvent nur ausgelöst, wenn der Spieler das erste Mal auf der Plattform landet. Um das Event wieder auslösbar zu machen, kannst du den Trigger zurücksetzen. Rufe in RecyclePlatform() Reset() auf der Plattform-Trigger auf, nachdem du Enable() aktiviert hast.

     # Blende die Platform aus und setze den PlatformTrigger zurück. Warte dann eine zufällige Zeitspanne und aktiviere die Anzeige der Plattform wieder.
 RecyclePlatform()<suspends> : void =

     # Warte DisappearDelay Sekunden.
     Sleep(DisappearDelay)

     # Blende die Platform aus und deaktiviere den Trigger.
     DisappearingPlatform.Hide()
     PlatformTrigger.Disable()

     # Warte zwischen DelayMin und DelayMax Sekunden.
     Sleep(GetRandomFloat(DelayMin, DelayMax))

     # Zeig die Plattform und aktiviere den Trigger.
     DisappearingPlatform.Show()
     PlatformTrigger.Enable()

     # Setzt die Anzahl der verzeichneten erlaubten Aktivierungen des Plattform-Triggers zurück.
     PlatformTrigger.Reset()

  4. Speichere das Script und klicke auf Verse, und dann auf Build Verse Code, um den Code zu kompilieren.

  5. Klicke auf Sitzung starten in der UEFN-Symbolleiste, um das Level zu testen.

  6. Wenn du dein Level jetzt testest, sollte jede Plattform verschwinden, wenn du auf ihr landest, und taucht eine zufällige Anzahl an Sekunden später wieder auf.

    Eine Plattform, die verschwindet, wenn der Spieler sie berührt, und nach einer zufälligen Anzahl von Sekunden wieder auftaucht, wenn sie berührt wird, mit Verse

Vollständiges Script

Der folgende Code ist das komplette Script, um eine Plattform verschwinden zu lassen, wenn der Spieler auf der Plattform landet und nach einer zufälligen Anzahl von Sekunden wieder aufzutauchen.

using { /Fortnite.com/Devices }
using { /Verse.org/Random }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/Diagnostics }

# Unter https://dev.epicgames.com/documentation/de-de/uefn/create-your-own-device-in-verse erfährst du, wie du ein Verse-Gerät erstellst.
# Ein mit Verse erstelltes Kreativmodus-Gerät, das in einem Level platziert werden kann
disappear_on_touch_platform := class(creative_device):

    # Wie lange wird gewartet, nachdem der Spieler die Plattform berührt hat, bevor sie versteckt wird.
    @editable
    DisappearDelay:float = 1.0

    # Die Mindestzeit, die gewartet werden muss, bevor die Plattform wieder auftaucht.
    @editable
    DelayMin:float = 3.0

    # Die maximale Zeit, die gewartet werden muss, bevor die Plattform wieder auftaucht.
    @editable
    DelayMax:float = 4.0

    # Bezug auf die Plattform im Level.
    @editable
    DisappearingPlatform:creative_prop = creative_prop{}

    # Die Zone die ein Spieler betritt, wenn er auf der Plattform landet.
    @editable
    PlatformTrigger:trigger_device = trigger_device{}

    # Wird ausgeführt, wenn das Gerät in einem laufenden Spiel gestartet wird
    OnBegin<override>()<suspends>:void=

        # Abonnieren des TriggeredEvent des Plattformtriggers, um zu wissen,
        # wenn ein Spieler auf der Plattform landet.
        PlatformTrigger.TriggeredEvent.Subscribe(OnPlayerTouch)

    # Läuft, wenn ein Spieler auf der Plattform landet. Ruf RecyclePlatform() auf, um die Plattform zu verbergen.
    # und setzt den Triggerzustand zurück.
    OnPlayerTouch(ActivatingPlayer:?agent):void=
        if:
            Spieler:= ActivatingPlayer?
        then:
            Print("Ein Spieler hat eine Plattform berührt!")
            spawn{ RecyclePlatform() }

    # Blende die Platform aus und setze den PlatformTrigger zurück. Warte dann eine zufällige Zeitspanne und aktiviere die Anzeige der Plattform wieder.
    RecyclePlatform()<suspends> : void =

        # Warte DisappearDelay Sekunden.
        Sleep(DisappearDelay)

        # Blende die Platform aus und deaktiviere den Trigger.
        DisappearingPlatform.Hide()
        PlatformTrigger.Disable()

        # Warte zwischen DelayMin und DelayMax Sekunden.
        Sleep(GetRandomFloat(DelayMin, DelayMax))

        # Zeig die Plattform und aktiviere den Trigger.
        DisappearingPlatform.Show()
        PlatformTrigger.Enable()

        # Setzt die Anzahl der verzeichneten erlaubten Aktivierungen des Plattform-Triggers zurück.
        PlatformTrigger.Reset()

Auf eigene Faust

Wenn du dieses Tutorial abgeschlossen hast, hast du gelernt, wie du mit Verse ein Gerät erstellst, das eine Plattform verschwinden lässt, wenn der Spieler darauf landet, und nach einer zufälligen Anzahl von Sekunden wieder auftaucht.

Versuche mit dem, was du gelernt hast, Folgendes:

  • Spiele mit den Größen und Positionen der Plattformen, um eine interessante Herausforderung zu schaffen.

  • In diesem Beispiel bekommt der Spieler keine Punkte und es passiert nichts, wenn er fällt. Kannst du dir vorstellen, wie du ein Punktesystem und eine Niederlagenbedingung einführen würdest?

Ask questions and help your peers Developer Forums

Write your own tutorials or read those from others Learning Library

On this page